MPZI_vj08_s_izradom -- Sage

Integrali i diferencijalne jednadžbe

Neodređeni integral

1. zadatak

Zadana je funkcija $f(x) = x\,\ln\,x + x^2$ . Izračunajte neodređeni integral funkcije $f(x)$ . Deriviranjem funkcije dobivene integriranjem provjerite rezultat.

f(x) = x*log(x) + x^2
f

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ x^{2} + x \log\left(x\right)$

g(x) = integral (f, x)
g

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ \frac{1}{3} \, x^{3} + \frac{1}{2} \, x^{2} \log\left(x\right) - \frac{1}{4} \, x^{2}$

... ili:

g(x) = integrate (f(x), x)
g

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ \frac{1}{3} \, x^{3} + \frac{1}{2} \, x^{2} \log\left(x\right) - \frac{1}{4} \, x^{2}$

... strogo matematički:

var ('C')
g(x) = integral (f, x) + C
g

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ \frac{1}{3} \, x^{3} + \frac{1}{2} \, x^{2} \log\left(x\right) - \frac{1}{4} \, x^{2} + C$

h(x) = diff (g, x)
h

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ x^{2} + x \log\left(x\right)$

bool (f == h)

$\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{True}$

2. zadatak

Koju funkciju treba derivirati da se dobije funkcija $\displaystyle f(x) = e^{x+1}\cos(4x)$ ? Deriviranjem provjerite dobiveni rezultat (za „vizualnu” će vam usporedbu trebati i funkcija .simplify_full()).

Uputa: tražena je funkcija neodređeni integral zadane funkcije $f(x)$ .

f(x) = exp(x+1)*cos(4*x)
f

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ \cos\left(4 \, x\right) e^{\left(x + 1\right)}$

g(x) = integral (f, x) + C
g

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ \frac{1}{17} \, {\left(\cos\left(4 \, x\right) + 4 \, \sin\left(4 \, x\right)\right)} e^{\left(x + 1\right)} + C$

h(x) = diff (g, x)
h

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ \frac{4}{17} \, {\left(4 \, \cos\left(4 \, x\right) - \sin\left(4 \, x\right)\right)} e^{\left(x + 1\right)} + \frac{1}{17} \, {\left(\cos\left(4 \, x\right) + 4 \, \sin\left(4 \, x\right)\right)} e^{\left(x + 1\right)}$

h.simplify_full()

$\newcommand{\Bold}[1]{\mathbf{#1}}8 \, e^{\left(x + 1\right)} \sin\left(x\right)^{4} - 8 \, e^{\left(x + 1\right)} \sin\left(x\right)^{2} + e^{\left(x + 1\right)}$

f.simplify_full()

$\newcommand{\Bold}[1]{\mathbf{#1}}8 \, e^{\left(x + 1\right)} \sin\left(x\right)^{4} - 8 \, e^{\left(x + 1\right)} \sin\left(x\right)^{2} + e^{\left(x + 1\right)}$

... za razliku od nas Sage za usporedbu ne treba pomoć funkcije .simplify_full():

bool (h == f)

$\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{True}$

1. zadatak za zadaću

Koju funkciju treba derivirati da se dobije funkcija $f(x)=x^3\mathrm{arctg}\; x$ ? Dobiveni rezultat provjerite deriviranjem.

Određeni integral

3. zadatak

Izračunajte određeni integral $\displaystyle \int_{-\infty}^{\infty} \frac{1}{x^2+2x+5}\, dx$ .

integral (1 / (x^2 + 2*x + 5), x, -oo, oo)

$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{2} \, \pi$

... ili:

integrate (1 / (x^2 + 2*x + 5), x, -oo, oo)

$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{2} \, \pi$

4. zadatak

(Primjena u kinematici) Točka se giba po pravcu. Njezina brzina $v$ , ovisna o vremenu $t$ , zadana je formulom $\displaystyle v(t) = 0,\!3\,\cos\frac{t}{2} + 0,\!5$ . Koliki put pređe točka od $t_1 = 0,\!2$ do $t_2=1$ sekundi?

Uputa: duljina puta jednaka je određenom integralu brzine od $t_1$ do $t_2$ .

Rješavanje neposrednom primjenom određenoga integrala:

var ('t')
integral (0.3*cos(t/2) + 0.5, t, 0.2, 1)

$\newcommand{\Bold}[1]{\mathbf{#1}}0.6277552731744249$

Rješavanje primjenom neodređenoga integrala i Newton–Leibnizove formule:

s(t) = integral (0.3*cos(t/2) + 0.5, t)
s

$\newcommand{\Bold}[1]{\mathbf{#1}}t \ {\mapsto}\ 0.5 \, t + 0.6 \, \sin\left(\frac{1}{2} \, t\right)$

s(1.) - s(0.2)

$\newcommand{\Bold}[1]{\mathbf{#1}}0.627755273174425$

2. zadatak za zadaću

Točka se giba brzinom $v(t)= t + \sqrt{t}$ . Hoće li točka preći dulji put u prvih sedam sekundi ili između osme i jedanaeste sekunde?

5. zadatak

Odredite duljinu luka grafa funkcije $f(x)=\sin 2x$ nad segmentom $[0,\pi/4]$ .

Uputa: duljina luka krivulje $y=f(x)$ nad segmentom $[a,\, b]$ jednaka je $\displaystyle \int_a^b \sqrt{1+(f'(x))^2}\,dx$ .

„Točna” integracija:

f(x) =  sin (2*x)
f

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ \sin\left(2 \, x\right)$

df(x) = diff (f, x)
dluka = integral (sqrt (1 + (df(x))^2), x, 0, pi/4)
dluka

$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{6}$

... : dobiveni rezultat nije ispravan — budući da funkcija $f$ poprima u $0$ vrijednost $0$ , a u $\frac{\pi}{4}$ vrijednost $1$ , duljina luka mora biti veća od $1$ ; štoviše, duljina mora biti veća od $\sqrt{\big(\frac{\pi}{4}\big)^2 + 1^2} \approx 1,\!27$ :

plot (f, 0, pi/4) + plot (4*x/pi, 0, pi/4, color = 'red', figsize =  6)

integral (sqrt (1 + (diff (4*x/pi))^2), x, 0, pi/4)

$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{4} \, \pi \sqrt{\frac{16}{\pi^{2}} + 1}$

N (_)

$\newcommand{\Bold}[1]{\mathbf{#1}}1.27155427531352$

Numerička integracija daje ispravnu, iako samo približnu vrijednost:

rez = numerical_integral (sqrt(1. + (df(x))^2), 0, pi/4)
rez

$\newcommand{\Bold}[1]{\mathbf{#1}}\left(1.3175917907978152, 1.462820743200827 \times 10^{-14}\right)$

Funkcija numerical_integral() kao rezultat vraća par brojeva; prvi je numerička vrijednost integrala, a drugi ocjena greške.

rez[0]

$\newcommand{\Bold}[1]{\mathbf{#1}}1.3175917907978152$

... ili:

duljina_luka, greska = numerical_integral (sqrt(1. + (df(x))^2), 0, pi/4)
duljina_luka

$\newcommand{\Bold}[1]{\mathbf{#1}}1.3175917907978152$

... duljina luka leži u intervalu

[N (duljina_luka - greska), N (duljina_luka + greska)]

$\newcommand{\Bold}[1]{\mathbf{#1}}\left[1.31759179079780, 1.31759179079783\right]$

3. zadatak za zadaću

Odredite duljinu luka parabole $f(x) = 3x^2$ od $x_1 = 1$ do $x_2 = 4$ .

Napomena: za izračunavanje ove duljine luka nije nužna numerička integracija, već se zadatak može riješiti i „simboličkom” funkcijom integral(). Pokušajte.

4. zadatak za zadaću

Odredite duljinu luka krivulje koja je graf funkcije $f(x) = 4\,\mathrm{ln}(x^2+1)$ za $2 < x < 3$ .

Napomena: zadatak se ne može riješiti simboličkim integriranjem pomoću funkcije integral() (ipak, pokušajte), već se mora primijeniti numerička integracija funkcijom numerical_integral().

6. zadatak

Definirajte funkciju $f(x)=x+\sin(x^2+5)$ .
Nacrtajte graf funkcije nad segmentom $[1,\,3]$ i opcijom osjenčajte dio od osi $x$ do grafa. (Uočite da je funkcija nad zadanim segmentom pozitivna.)
Izračunajte ploštinu površine koja se proteže od zadanoga segmenta do grafa zadane funkcije.

Uputa: ako je funkcija pozitivna na segmentu, onda je ploština jednaka određenom integralu na tom segmentu.

f(x) = x + sin (x^2 + 5)
plot (f, 1, 3, fill = True, figsize =  6)

integral (f, x, 1, 3)

$\newcommand{\Bold}[1]{\mathbf{#1}}-\frac{1}{16} \, \sqrt{\pi} {\left({\left(-\left(i + 1\right) \, \sqrt{2} \cos\left(5\right) + \left(i - 1\right) \, \sqrt{2} \sin\left(5\right)\right)} \operatorname{erf}\left(\left(\frac{3}{2} i + \frac{3}{2}\right) \, \sqrt{2}\right) + {\left(\left(i + 1\right) \, \sqrt{2} \cos\left(5\right) - \left(i - 1\right) \, \sqrt{2} \sin\left(5\right)\right)} \operatorname{erf}\left(\left(\frac{1}{2} i + \frac{1}{2}\right) \, \sqrt{2}\right) + {\left(\left(i - 1\right) \, \sqrt{2} \cos\left(5\right) - \left(i + 1\right) \, \sqrt{2} \sin\left(5\right)\right)} \operatorname{erf}\left(\left(\frac{1}{2} i - \frac{1}{2}\right) \, \sqrt{2}\right) + {\left(-\left(i - 1\right) \, \sqrt{2} \cos\left(5\right) + \left(i + 1\right) \, \sqrt{2} \sin\left(5\right)\right)} \operatorname{erf}\left(\left(\frac{3}{2} i - \frac{3}{2}\right) \, \sqrt{2}\right) + {\left(\left(i - 1\right) \, \sqrt{2} \cos\left(5\right) - \left(i + 1\right) \, \sqrt{2} \sin\left(5\right)\right)} \operatorname{erf}\left(3 \, \sqrt{-i}\right) + {\left(-\left(i - 1\right) \, \sqrt{2} \cos\left(5\right) + \left(i + 1\right) \, \sqrt{2} \sin\left(5\right)\right)} \operatorname{erf}\left(\sqrt{-i}\right) + {\left(-\left(i + 1\right) \, \sqrt{2} \cos\left(5\right) + \left(i - 1\right) \, \sqrt{2} \sin\left(5\right)\right)} \operatorname{erf}\left(3 \, \left(-1\right)^{\frac{1}{4}}\right) + {\left(\left(i + 1\right) \, \sqrt{2} \cos\left(5\right) - \left(i - 1\right) \, \sqrt{2} \sin\left(5\right)\right)} \operatorname{erf}\left(\left(-1\right)^{\frac{1}{4}}\right)\right)} + 4$

N (_)

$\newcommand{\Bold}[1]{\mathbf{#1}}4.32479637388442$

... ili:

numerical_integral (f, 1, 3)

$\newcommand{\Bold}[1]{\mathbf{#1}}\left(4.324796373884419, 4.8014885111018686 \times 10^{-14}\right)$

5. zadatak za zadaću

Definirajte funkciju $\displaystyle f(x)=-\frac{\ln\,x}{x^2+1}$ .
Nacrtajte graf funkcije nad segmentom $[1,\,2]$ i opcijom osjenčajte dio od osi $x$ do grafa. (Uočite da je funkcija nad zadanim segmentom negativna.)
Izračunajte ploštinu površine koja se proteže od zadanoga segmenta do grafa funkcije.

Uputa: ako je funkcija negativna na segmentu, onda je ploština jednaka apsolutnoj vrijednosti određenoga integrala na tom segmentu.

6. zadatak za zadaću

Izračunajte ploštinu osjenčane površine, omeđene grafovima funkcija $f(x) = 2\,\sin (4\,x) + 1$ i $g(x) = -\dfrac{\sin (8\,x)}{2} + 1$ nad segmentom $[0, \pi/4]$ :

plot (2*sin (4*x) + 1, 0, pi/4, fill = True) + plot (-sin (8*x)/2 + 1, 0, pi/4, fill = True, fillcolor = 'white', fillalpha = 1, figsize = 6)

Uputa: tražena je ploština $\displaystyle A \;\,=\, \int_0^\pi f(x)\,dx - \int_0^\pi g(x)\,dx \,\;=\, \int_0^\pi \big(f(x) - g(x)\big)\,dx$ .

7. zadatak

Definirajte funkciju $h(x)=3-x-\sin\,x^2$ .
Nacrtajte njezin graf nad segmentom $[0;\,2,\!5]$ i osjenčajte dio ravnine između osi $x$ i grafa.
Izračunajte obujam rotacijskoga tijela koje nastaje rotacijom oko osi $y$ dijela ravnine omeđene grafom i segmentom osi $x$ .

Uputa: obujam tijela nastaloga rotacijom površine oko osi $y$ računa se po formuli $\displaystyle V_y = 2\pi \int_a^b x\cdot h(x)\, dx$ .

h(x) = 3 - x - sin(x^2)
plot (h, 0, 2.5, fill = True, figsize = 6)

2 * pi * integrate (x*h(x), x, 0, 2.5)

$\newcommand{\Bold}[1]{\mathbf{#1}}8.332782751557833 \, \pi$

N (_)

$\newcommand{\Bold}[1]{\mathbf{#1}}26.1782090762538$

Plohu koja nastaje rotacijom grafa funkcije $h(x)$ oko $y$ osi možemo prikazati pomoću funkcije revolution_plot3d():

revolution_plot3d ((x, h(x)), (x, 0, 2.5), aspect_ratio = 1, frame = false, show_curve = true)

Click on 3-D image to make it live. Right-click on live image for a control menu.

7. zadatak za zadaću

Izračunajte obujam tijela koje nastaje kada površina osjenčana u 7. zadatku rotira oko osi $x$ .

Uputa: formula za obujam koji nastaje rotacijom površine oko osi $x$ jest $\displaystyle V_x = \pi \int_a^b f^2(x)\, dx$ .

Diferencijalne jednadžbe

8. zadatak

Neka je $y(x)$ nepoznata funkcija. Riješite diferencijalnu jednadžbu $y'(x) - y(x) = x + 1$ .

y = function ('y')(x)
y(x) = desolve (diff (y, x) - y == x + 1, y)
y

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ -{\left({\left(x + 1\right)} e^{\left(-x\right)} - C + e^{\left(-x\right)}\right)} e^{x}$

y.simplify_full()

$\newcommand{\Bold}[1]{\mathbf{#1}}C e^{x} - x - 2$

8. zadatak za zadaću

Riješite diferencijalnu jednadžbu $2y'(x) - \displaystyle \frac{y(x)}{x} = x^2$ .

9. zadatak

Riješite diferencijalnu jednadžbu $x\, y'(x) - y(x) = x^3$ uz početni uvjet $y(1) = 2$ .

(ics je skraćenica od "Initial ConditionS" — početni uvjeti)

y = function ('y')(x)
y(x) = desolve (x*diff (y, x) - y == x^3, y, ics = [1, 2])
y

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ \frac{1}{2} \, x^{3} + \frac{3}{2} \, x$

9. zadatak za zadaću

Riješite diferencijalnu jednadžbu $y'(x) - x\,y(x) = x$ uz početni uvjet $y(0) = 2$ .

Rješenja zadataka za zadaću

Rješenje 1. zadatka za zadaću

Koju funkciju treba derivirati da se dobije funkcija $f(x)=x^3\mathrm{arctg}\; x$ ? Dobiveni rezultat provjerite deriviranjem.

var ('C')
f(x) = x^3*arctan(x)
g(x) = integral (f(x), x) + C
g

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ \frac{1}{4} \, x^{4} \arctan\left(x\right) - \frac{1}{12} \, x^{3} + C + \frac{1}{4} \, x - \frac{1}{4} \, \arctan\left(x\right)$

diff (g, x)

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ x^{3} \arctan\left(x\right) + \frac{x^{4}}{4 \, {\left(x^{2} + 1\right)}} - \frac{1}{4} \, x^{2} - \frac{1}{4 \, {\left(x^{2} + 1\right)}} + \frac{1}{4}$

_.simplify_full()

$\newcommand{\Bold}[1]{\mathbf{#1}}x^{3} \arctan\left(x\right)$

bool (f == diff (g, x))

$\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{True}$

Rješenje 2. zadatka za zadaću

Točka se giba brzinom $v(t)= t + \sqrt{t}$ . Hoće li točka preći dulji put u prvih sedam sekundi ili između osme i jedanaeste sekunde?

var('t')
v(t) = t + sqrt(t)
put1 = integral (v(t), t, 0, 7)
put2 = integral (v(t), t, 8, 11)
N (put1); N (put2)

$\newcommand{\Bold}[1]{\mathbf{#1}}36.8468394516348$

$\newcommand{\Bold}[1]{\mathbf{#1}}37.7369704639599$

max (N (put1), N (put2))

$\newcommand{\Bold}[1]{\mathbf{#1}}37.7369704639599$

N (put1) > N (put2)

$\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{False}$

Zaključak: dulji će put točka preći između osme i jednaeste sekunde.

Rješenje 3. zadatka za zadaću

Odredite duljinu luka parabole $f(x) = 3x^2$ od $x_1 = 1$ do $x_2 = 4$ .

f(x) = 3*x^2
g(x) = diff (f(x), x)
f; g

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ 3 \, x^{2}$

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ 6 \, x$

... simbolički:

dluka = integral (sqrt (1 + g(x)^2), x, 1, 2)
N (dluka)

$\newcommand{\Bold}[1]{\mathbf{#1}}9.05754711239777$

... numerički:

dluka_n, gr = numerical_integral (sqrt (1 + g(x)^2), 1, 2)
dluka_n, gr

$\newcommand{\Bold}[1]{\mathbf{#1}}\left(9.057547112397764, 1.0055897350811098 \times 10^{-13}\right)$

... dakle, duljina luka leži u intervalu

[N (dluka_n - gr), N (dluka_n + gr)]

$\newcommand{\Bold}[1]{\mathbf{#1}}\left[9.05754711239766, 9.05754711239786\right]$

Rješenje 4. zadatka za zadaću

Odredite duljinu luka krivulje koja je graf funkcije $f(x) = 4\,\mathrm{ln}(x^2+1)$ za $2 < x < 3$ .

f(x) = 4*log (x^2 + 1)
g(x) = derivative (f(x), x)
dluka = integral (sqrt (1 + g(x)^2), x, 2, 3)
dluka

$\newcommand{\Bold}[1]{\mathbf{#1}}\int_{2}^{3} \sqrt{\frac{64 \, x^{2}}{{\left(x^{2} + 1\right)}^{2}} + 1}\,{d x}$

dluka = numerical_integral (sqrt (1 + g(x)^2), 2, 3)
dluka

$\newcommand{\Bold}[1]{\mathbf{#1}}\left(2.94845650680337, 3.273444300958961 \times 10^{-14}\right)$

Rješenje 5. zadatka za zadaću

Definirajte funkciju $\displaystyle f(x)=-\frac{\ln\,x}{x^2+1}$ .
Nacrtajte graf funkcije nad segmentom $[1,\,2]$ i opcijom osjenčajte dio od osi $x$ do grafa. (Uočite da je funkcija nad zadanim segmentom negativna.)
Izračunajte ploštinu površine koja se proteže od zadanoga segmenta do grafa funkcije.

Uputa: ako je funkcija negativna na segmentu, onda je ploština jednaka apsolutnoj vrijednosti određenoga integrala po tom segmentu.

f(x) = -log(x) / (x^2 + 1)
plot (f(x), (x, 1.5, 2), fill = True, figsize = 6)

plostina, greska = numerical_integral (f(x), 1.5, 2)
plostina, greska

$\newcommand{\Bold}[1]{\mathbf{#1}}\left(-0.06788249400308537, 7.536470781120449 \times 10^{-16}\right)$

abs (plostina)

$\newcommand{\Bold}[1]{\mathbf{#1}}0.06788249400308537$

Rješenje 6. zadatka za zadaću

Izračunajte ploštinu površine omeđene grafovima funkcija $f(x) = 2\,\sin (4\,x) + 1$ i $g(x) = -\dfrac{\sin (8\,x)}{2} + 1$ nad segmentom $[0, \pi/4]$ .

Uputa: tražena je ploština $\displaystyle A \;\,=\, \int_0^\pi f(x)\,dx - \int_0^\pi g(x)\,dx \,\;=\, \int_0^\pi \big(f(x) - g(x)\big)\,dx$ .

A = integral (2*sin (4*x) + 1, (x, 0, pi/4) ) - integral( -sin(8*x)/2 + 1, x, 0, pi/4)
A

$\newcommand{\Bold}[1]{\mathbf{#1}}1$

... ili:

A = integral (2*sin (4*x) + 1 - (-sin(8*x)/2 + 1), x, 0, pi/4)
A

$\newcommand{\Bold}[1]{\mathbf{#1}}1$

Rješenje 7. zadatka za zadaću

Izračunajte obujam tijela koje nastaje kada površina osjenčana u 7. zadatku rotira oko osi $x$ .

Uputa: formula za obujam koji nastaje rotacijom površine oko osi $x$ glasi $\displaystyle V_x = \pi \int_a^b f^2(x)\, dx$ .

h(x) = 3 - x - sin(x^2)
volumen = pi * integral (h(x)^2, x, 0, 2.5)
volumen

$\newcommand{\Bold}[1]{\mathbf{#1}}\pi {\left(\sqrt{\pi} {\left(-\left(0.375 + 0.375i\right) \, \sqrt{2} \operatorname{erf}\left(\left(1.25 + 1.25i\right) \, \sqrt{2}\right) + \left(0.375 - 0.375i\right) \, \sqrt{2} \operatorname{erf}\left(-\left(1.25 - 1.25i\right) \, \sqrt{2}\right) - \left(0.375 - 0.375i\right) \, \sqrt{2} \operatorname{erf}\left(2.5 \, \sqrt{-i}\right) - \left(0.375 + 0.375i\right) \, \sqrt{2} \operatorname{erf}\left(2.5 \, \left(-1\right)^{\frac{1}{4}}\right) - 0.12203649614275235\right)} + 10.208883915108832\right)}$

N (volumen)

$\newcommand{\Bold}[1]{\mathbf{#1}}23.2775471845893$

Plohu koja nastaje rotacijom grafa funkcije $h(x)$ oko $x$ osi možemo vidjeti pomoću funkcije revolution_plot3d():

revolution_plot3d ((x, h(x)), (x, 0, 2.5), parallel_axis = 'x', aspect_ratio = 1, frame = false, show_curve=true)

Rješenje 8. zadatka za zadaću

Riješite diferencijalnu jednadžbu $2y'(x) - \displaystyle \frac{y(x)}{x} = x^2$ .

y = function ('y')( x)
y(x) = desolve (2*diff (y, x) - y/x == x^2, y)
y

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ \frac{1}{5} \, {\left(x^{\frac{5}{2}} + 5 \, C\right)} \sqrt{x}$

y.simplify_full()

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ \frac{1}{5} \, x^{3} + C \sqrt{x}$

Rješenje 9. zadatka za zadaću

Riješite diferencijalnu jednadžbu $y'(x) - x\,y(x) = x$ uz početni uvjet $y(0) = 2$ .

y = function ('y')( x)
y(x) = desolve (diff (y, x) + x*y == x, y, ics = [0, 2])
y

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ {\left(e^{\left(\frac{1}{2} \, x^{2}\right)} + 1\right)} e^{\left(-\frac{1}{2} \, x^{2}\right)}$

MPZI_vj08_s_izradom

2423 days ago by fresl