MPZI_vj06_s_izradom -- Sage

Jednadžbe, sustavi jednadžbi i nejednadžbe

Rješenja jednadžbi koje su zadane simboličkim izrazima u obliku polinoma

1. zadatak

Definirajte funkciju $f(x)=x^4-\dfrac{2}{3}x^3 - \dfrac{26}{9}x^2 + 2x - \dfrac{1}{3}$ i riješite jednadžbu $f(x) = 0$ . Izdvojite prvo rješenje pa odredite decimalni prikaz tog rješenja na 20 znamenaka. Izračunavanjem vrijednosti funkcije $f$ u prvom rješenju provjerite da je dobiveni rezultat zaista rješenje.

f(x) = x^4 - 2/3*x^3 - 26/9*x^2 + 2*x - 1/3
show (f)

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ x^{4} - \frac{2}{3} \, x^{3} - \frac{26}{9} \, x^{2} + 2 \, x - \frac{1}{3}$

rj = solve (f(x) == 0, x)
show (rj)

$\newcommand{\Bold}[1]{\mathbf{#1}}\left[x = -\sqrt{3}, x = \sqrt{3}, x = \left(\frac{1}{3}\right)\right]$

Prvo rješenje je

rj[0]

x == -sqrt(3)

x == -sqrt(3)

njegova je numerička vrijednost

rj0 = rj[0].right()
rj0

-sqrt(3)

-sqrt(3)

... ili

rj[0].rhs()

-sqrt(3)

-sqrt(3)

Decimalni je prikaz rješenja

N (rj0, digits = 20)

-1.7320508075688772935

-1.7320508075688772935

... ili

rj0.n (digits = 20)

-1.7320508075688772935

-1.7320508075688772935

Provjera da je dobiveni rezultat zaista rješenje:

f (rj0)

Numerička provjera:

f (N (rj0))

-1.77635683940025e-15

-1.77635683940025e-15

— dobivena je vrijednost dovoljno mala da je možemo zanemariti i smatrati jednakom nuli.

2. zadatak

Odredite rješenje iste jednadžbe kao u prvom zadatku, ali odredite i „kratnost” rješenja.

rj = solve (f(x) == 0, x, multiplicities = True)
rj

([x == -sqrt(3), x == sqrt(3), x == (1/3)], [1, 1, 2])

([x == -sqrt(3), x == sqrt(3), x == (1/3)], [1, 1, 2])

plot (f, -2, 2.)

u točki $\bigg(\dfrac{1}{3}, 0\bigg)$ graf funkcije $f$ dira os $x$ , pa je to dvostruka nul–točka.

1. zadatak za zadaću

Definirajte funkciju $f(x) = x^3- x^2 - 6$ i nađite njezine nul–točke. Ispišite numeričku vrijednost posljednje nul–točke, pridružite je varijabli $\mathtt{x1}$ i provjerite, izračunavanjem $f(\mathtt{x1})$ , da je $\mathtt{x1}$ nul–točka.

(Rješenje se nalazi pri dnu radnog lista.)

Nul–točke polinoma

3. zadatak

Definirajte funkciju $f(x) = 2x^9- 3x^7+ x^2 - 3x - 4$ pa pokušajte, pomoću funkcije , riješiti jednadžbu $f(x) = 0$ .

Primjenom funkcije uvedite polinom nad realnim brojevima zadan funkcijom $f$ i nazovite ga $\mathtt{polr}$ . Odredite realne nul–točke polinoma $\mathtt{polr}$ , izdvojite prvo rješenje te provjerite je li dobiveni rezultat nul–točka zadanoga polinoma.

Ponovnom primjenom funkcije . uvedite polinom nad kompleksnim brojevima zadan istom funkcijom; nazovite ga $\mathtt{polc}$ . Odredite sve nul–točke polinoma $\mathtt{polc}$ , izdvojite prvo rješenje koje nije realno te provjerite je li dobiveni rezultat nul–točka zadanoga polinoma.

f(x) = 2*x^9 - 3*x^7 + x^2 - 3*x - 4
show (f)

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ 2 \, x^{9} - 3 \, x^{7} + x^{2} - 3 \, x - 4$

solve (f(x) == 0, x)

[0 == 2*x^9 - 3*x^7 + x^2 - 3*x - 4]

[0 == 2*x^9 - 3*x^7 + x^2 - 3*x - 4]

Funkcija solve() ne daje rješenje.

Transformacija funkcije u polinom nad skupom realnih brojeva i traženje realnih nul–točaka:

polr = f.polynomial (RR)
rj = polr.roots()
rj

[(-1.27744972439006, 1), (-0.879070264182932, 1), (1.36272304386257, 1)]

[(-1.27744972439006, 1), (-0.879070264182932, 1), (1.36272304386257, 1)]

Prvo rješenje:

x0 = rj[0][0]
x0

-1.27744972439006

-1.27744972439006

polr (x0)

8.88178419700125e-16

8.88178419700125e-16

Transformacija funkcije u polinom nad skupom kompleksnih brojeva i traženje svih nul–točaka:

polc = f.polynomial (CC)
rjc = polc.roots (multiplicities = False)
rjc

[-1.27744972439006,
 -0.879070264182932,
 1.36272304386257,
 -0.673071323697214 - 0.743074446894458*I,
 -0.673071323697214 + 0.743074446894458*I,
 0.144190063769222 - 1.01696902072154*I,
 0.144190063769222 + 1.01696902072154*I,
 0.925779732283200 - 0.612638949332554*I,
 0.925779732283200 + 0.612638949332554*I]

[-1.27744972439006,
 -0.879070264182932,
 1.36272304386257,
 -0.673071323697214 - 0.743074446894458*I,
 -0.673071323697214 + 0.743074446894458*I,
 0.144190063769222 - 1.01696902072154*I,
 0.144190063769222 + 1.01696902072154*I,
 0.925779732283200 - 0.612638949332554*I,
 0.925779732283200 + 0.612638949332554*I]

Prvo kompleksno rješenje:

x3 = rjc[3]
x3

-0.673071323697214 - 0.743074446894458*I

-0.673071323697214 - 0.743074446894458*I

polc (x3)

1.77635683940025e-15 - 2.88657986402541e-15*I

1.77635683940025e-15 - 2.88657986402541e-15*I

2. zadatak za zadaću

Neka je $f(x) = x^6 -2x^2 +x - 1$ . Pokušajte, pomoću funkcije , riješiti jednadžbu $f(x) = 0$ .

Pretvorite $f$ u polinom nad skupom realnih brojeva i odredite mu realne nul–točke. Izdvojite zadnje realno rješenje pa provjerite da je to zaista nul–točka.

Pretvorite $f$ u polinom nad skupom kompleksnih brojeva i odredite mu sve nul–točke. Izdvojite zadnje rješenje koje nije realno pa provjerite da je to zaista nul–točka.

Numeričko (približno) rješavanje jedne jednadžbe s jednom nepoznanicom

4. zadatak

Numerički odredite negativnu nul–točku funkcije $f(x)=\sin(x)-x^3$ . Za određivanje intervala u kojemu leži tražena nul–točka nacrtajte graf na intervalu $(-2, 2)$ , a zatim se „približite” negativnoj nul–točki.

Provjerite da je dobiveni broj zaista rješenje.

Za vježbu odredite pozitivnu nul–točku funkcije (rezultat: $x_0 \approx 0,\!928\,626$ ).

f(x) = sin(x) - x^3

plot (f, -2, 2)

plot (f, -1.2, -0.6)

rj = find_root (f, -1, -0.9)
rj

-0.9286263087317345

-0.9286263087317345

f(rj)

0.000000000000000

0.000000000000000

Rješenje vježbe:

plot (f, 0.8, 1.)

find_root (f, 0.9, 0.95)

0.9286263087315713

0.9286263087315713

f(_)

3.24407167795471e-13

3.24407167795471e-13

5. zadatak

Jednadžba $\displaystyle \sqrt{x^2+1} - \mathrm{tg}\,x = 0$ ima beskonačno mnogo rješenja. Da biste predočili tu činjenicu nacrtajte graf funkcije $f(x)$ za $-10\le x\le 10$ ; za bolji prikaz slike upotrijebite opcije ymin = -2 , ymax = 2 te detect_poles = 'show'.

Numerički odredite najmanje pozitivno rješenje jednadžbe $\displaystyle \sqrt{x^2+1} - \mathrm{tg}\,x = 0$ . Za određivanje „maloga” intervala u kojemu se nalazi rješenje nacrtajte graf za $x\in[0, 1]$ .

Provjerite da je dobiveni rezultat zaista rješenje.

Za vježbu nađite sljedeće po veličini rješenje. Uputa: nacrtajte graf za $x \in [4; 4,\!6]$ (rezultat: $x_0 \approx 4,\!498\,711\,86$ ).

f(x) = sqrt(x^2 + 1) - tan(x)

plot (f(x), (x, -10, 10))

plot (f(x), (x, -10, 10), ymin = -2, ymax = 2, detect_poles = 'show')

plot (f(x), 0, 1)

rj = find_root (f(x), 0.9, 1)
rj

0.9414615238528159

0.9414615238528159

f(rj)

0.000000000000000

0.000000000000000

Rješenje vježbe:

plot (f(x), (x, 4, 4.6))

find_root (f(x), 4.45, 4.55)

4.498711859419101

4.498711859419101

f(_)

-2.20090612401691e-12

-2.20090612401691e-12

3. zadatak za zadaću

Numerički odredite nul–točku funkcije $f(x) = x^2 - 2 + \mathrm{ln}\,x$ .

Uputa: nacrtajte graf za $x\in[0, 2]$ .

Sustavi linearnih jednadžbi

6. zadatak

Riješite sustav

$2x + y + z = 4$

$x + 2y + z = 3$

$x + y + 2z = 2$

Koliko iznosi brojčana vrijednost komponente $y$ dobivenoga rješenja?

Koliko ste rješenja dobili?

var('x, y, z');
rj = solve ([2*x + y + z == 4, 
             x + 2*y + z == 3, 
             x + y + 2*z == 2], 
             [x, y, z]) 
rj

[[x == (7/4), y == (3/4), z == (-1/4)]]

[[x == (7/4), y == (3/4), z == (-1/4)]]

rj[0][1]

y == (3/4)

y == (3/4)

(rj[0][1]).right()

3/4

3/4

Dobili smo jedno rješenje (ili: rješenje je jedinstveno).

7. zadatak

Riješite sustav

$2x + y + z = 4$

$x + 2y + z = 3$

$3x + 3y + 2z = 2$

(Promjena u odnosu na prethodni zadatak je samo u koeficijentima uz x i y u trećoj jednadžbi.)

Koliko ste rješenja dobili?

rj = solve ([2*x + y + z == 4, 
             x + 2*y + z == 3, 
             3*x + 3*y + 2*z == 2], 
             [x, y, z])
rj

[]

[]

Nismo dobili ni jedno rješenje (ili: sustav nema rješenja).

8. zadatak

Riješite sustav

$2x + y + z = 4$

$x + 2y + z = 3$

$3x + 3y + 2z = 7$

(U odnosu na prethodni zadatak, promijenjena je samo desna strana zadnje jednadžbe.)

Koliko ste rješenja dobili?

rj = solve ([2*x + y + z == 4, 
             x + 2*y + z == 3, 
             3*x + 3*y + 2*z == 7], 
             [x, y, z])
rj

[[x == -1/3*r1 + 5/3, y == -1/3*r1 + 2/3, z == r1]]

[[x == -1/3*r1 + 5/3, y == -1/3*r1 + 2/3, z == r1]]

show (_)

$\newcommand{\Bold}[1]{\mathbf{#1}}\left[\left[x = -\frac{1}{3} \, r_{1} + \frac{5}{3}, y = -\frac{1}{3} \, r_{1} + \frac{2}{3}, z = r_{1}\right]\right]$

Dobili smo beskonačno mnogo rješenja; varijabla $z$ može imati bilo koju (realnu) vrijednost, a vrijednosti $x$ i $y$ ovise o vrijednosti varijable $z$ .

9. zadatak

Sustav (iz zadatka 6.)

$2x + y + z = 4$

$x + 2y + z = 3$

$x + y + 2z = 2$

riješite prevođenjem u matrični oblik. Uzmite da su komponente matrice $\mathbf{A}$ i vektora $\mathbf{b}$ racionalni brojevi.

A = matrix (QQ, 3, 3, [2, 1, 1, 1, 2, 1, 1, 1, 2])
show (A)

$\newcommand{\Bold}[1]{\mathbf{#1}}\left(\begin{array}{rrr} 2 & 1 & 1 \\ 1 & 2 & 1 \\ 1 & 1 & 2 \end{array}\right)$

b = vector (QQ, [4, 3, 2])
show (b.column())

$\newcommand{\Bold}[1]{\mathbf{#1}}\left(\begin{array}{r} 4 \\ 3 \\ 2 \end{array}\right)$

x = A.solve_right (b)
show (x.column())

$\newcommand{\Bold}[1]{\mathbf{#1}}\left(\begin{array}{r} \frac{7}{4} \\ \frac{3}{4} \\ -\frac{1}{4} \end{array}\right)$

... ili

x = A \ b
show (x.column())

$\newcommand{\Bold}[1]{\mathbf{#1}}\left(\begin{array}{r} \frac{7}{4} \\ \frac{3}{4} \\ -\frac{1}{4} \end{array}\right)$

reset ('x')

4. zadatak za zadaću

Riješite sustav

$-x + 2y +3z \,=\, 8$

$3x - y - z \,=\, -3$

$3x -3 y + 2 z \,=\,1$ .

Koliko iznosi numerička vrijednost varijable $z$ u rješenju? Koliko smo rješenja dobili?

Ako je rješenje jedinstveno, riješite sustav prevođenjem u matrični oblik (s komponentama u skupu $\mathbb{Q}$ ).

Nejednadžbe

10. zadatak

Odredite na kojem je podskupu realnih brojeva $x^2-1$ veće od $x^3-1$ , a na kojem je veće ili jednako?

solve (x^2-1 > x^3-1, x)

[[x < 0], [x > 0, x < 1]]

[[x < 0], [x > 0, x < 1]]

solve (x^2-1 >= x^3-1, x)

[[x <= 1]]

[[x <= 1]]

p1 = plot (x^2-1, -1.2, 1.2)
p2 = plot (x^3-1, -1.2, 1.2, color = 'red')
p1 + p2

11. zadatak

Odredite domenu funkcije $\displaystyle f(x)=\ln \frac{x-2}{x^2-9}$ .

Uputa: logaritam je definiran na skupu pozitivnih brojeva, pa mora vrijediti $\displaystyle \frac{x-2}{x^2-9} > 0$ . Uz to, mora biti $x^2-9 \ne 0$ .

plot (log ((x-2)/(x^2-9)), -10, 20)

verbose 0 (3532: plot.py, generate_plot_points) WARNING: When plotting, failed
to evaluate function at 54 points.
verbose 0 (3532: plot.py, generate_plot_points) Last error message: 'can't
convert complex to float'

verbose 0 (3532: plot.py, generate_plot_points) WARNING: When plotting, failed to evaluate function at 54 points.
verbose 0 (3532: plot.py, generate_plot_points) Last error message: 'can't convert complex to float'

solve ((x-2)/(x^2-9) > 0, x)

[[x > -3, x < 2], [x > 3]]

[[x > -3, x < 2], [x > 3]]

solve (x^2-9 == 0, x)

[x == -3, x == 3]

[x == -3, x == 3]

— funkcija $f$ definirana je na skupu $(-3, 2) \cup (3, \infty)$ .

12. zadatak

Odredite domenu funkcije $\displaystyle f(x) = \frac{\sqrt{1-x^2}}{\ln\, (2x-1)}$ .

Postupak:

da bi drugi korijen bio definiran treba veličina pod korijenom biti nenegativna tj. treba vrijediti $1 - x^2 \geq 0$ ,
da bi logaritam bio definiran njegov argument mora biti strogo pozitivan, tj. treba biti $2x - 1 > 0$ ,
da bi razlomak bio definiran nužno je da je nazivnik različit od 0, što znači da iz skupa dobivenoga iz prva dva uvjeta treba izbaciti rješenje jednadžbe $\ln\,(2x-1) = 0$ .

plot (sqrt (1 - x^2) / log (2*x - 1), -1, 2)

verbose 0 (3532: plot.py, generate_plot_points) WARNING: When plotting, failed
to evaluate function at 167 points.
verbose 0 (3532: plot.py, generate_plot_points) Last error message: 'math domain
error'

verbose 0 (3532: plot.py, generate_plot_points) WARNING: When plotting, failed to evaluate function at 167 points.
verbose 0 (3532: plot.py, generate_plot_points) Last error message: 'math domain error'

solve ([1 - x^2 >= 0, 2*x - 1 > 0], x)

[[(1/2) < x, x < 1], [x == 1]]

[[(1/2) < x, x < 1], [x == 1]]

solve (log(2*x - 1) == 0, x)

[x == 1]

[x == 1]

— domena funkcije $f$ je $(\frac{1}{2}, 1)$ .

5. zadatak za zadaću

Odredite na kojemu podskupu skupa $\mathbb{R}$ funkcija $f : x \mapsto 4\,x^3 - 8\,x^2 - 4\,x + 8$ poprima manje vrijednosti od funkcije $g : x \mapsto \dfrac{1}{x}$ .

Rješenje 1. zadatka za zadaću

f(x) = x^3 - x^2 - 6
rj = solve (f(x) == 0, x)
rj

[x == -1/6*(9*sqrt(83) + 82)^(1/3)*(I*sqrt(3) + 1) - 1/6*(-I*sqrt(3) +
1)/(9*sqrt(83) + 82)^(1/3) + 1/3, x == -1/6*(9*sqrt(83) + 82)^(1/3)*(-I*sqrt(3)
+ 1) - 1/6*(I*sqrt(3) + 1)/(9*sqrt(83) + 82)^(1/3) + 1/3, x == 1/3*(9*sqrt(83) +
82)^(1/3) + 1/3/(9*sqrt(83) + 82)^(1/3) + 1/3]

[x == -1/6*(9*sqrt(83) + 82)^(1/3)*(I*sqrt(3) + 1) - 1/6*(-I*sqrt(3) + 1)/(9*sqrt(83) + 82)^(1/3) + 1/3, x == -1/6*(9*sqrt(83) + 82)^(1/3)*(-I*sqrt(3) + 1) - 1/6*(I*sqrt(3) + 1)/(9*sqrt(83) + 82)^(1/3) + 1/3, x == 1/3*(9*sqrt(83) + 82)^(1/3) + 1/3/(9*sqrt(83) + 82)^(1/3) + 1/3]

show (rj)

$\newcommand{\Bold}[1]{\mathbf{#1}}\left[x = -\frac{1}{6} \, {\left(9 \, \sqrt{83} + 82\right)}^{\frac{1}{3}} {\left(i \, \sqrt{3} + 1\right)} - \frac{-i \, \sqrt{3} + 1}{6 \, {\left(9 \, \sqrt{83} + 82\right)}^{\frac{1}{3}}} + \frac{1}{3}, x = -\frac{1}{6} \, {\left(9 \, \sqrt{83} + 82\right)}^{\frac{1}{3}} {\left(-i \, \sqrt{3} + 1\right)} - \frac{i \, \sqrt{3} + 1}{6 \, {\left(9 \, \sqrt{83} + 82\right)}^{\frac{1}{3}}} + \frac{1}{3}, x = \frac{1}{3} \, {\left(9 \, \sqrt{83} + 82\right)}^{\frac{1}{3}} + \frac{1}{3 \, {\left(9 \, \sqrt{83} + 82\right)}^{\frac{1}{3}}} + \frac{1}{3}\right]$

len(rj)

Ne zaboravite, početna vrijednost indeksa je 0!

rj[2]

x == 1/3*(9*sqrt(83) + 82)^(1/3) + 1/3/(9*sqrt(83) + 82)^(1/3) + 1/3

x == 1/3*(9*sqrt(83) + 82)^(1/3) + 1/3/(9*sqrt(83) + 82)^(1/3) + 1/3

... ili

rj[-1]

x == 1/3*(9*sqrt(83) + 82)^(1/3) + 1/3/(9*sqrt(83) + 82)^(1/3) + 1/3

x == 1/3*(9*sqrt(83) + 82)^(1/3) + 1/3/(9*sqrt(83) + 82)^(1/3) + 1/3

x1 = rj[-1].rhs()
x1

1/3*(9*sqrt(83) + 82)^(1/3) + 1/3/(9*sqrt(83) + 82)^(1/3) + 1/3

1/3*(9*sqrt(83) + 82)^(1/3) + 1/3/(9*sqrt(83) + 82)^(1/3) + 1/3

N (x1)

2.21877658530167

2.21877658530167

f (x1)

1/27*((9*sqrt(83) + 82)^(1/3) + 1/(9*sqrt(83) + 82)^(1/3) + 1)^3 -
1/9*((9*sqrt(83) + 82)^(1/3) + 1/(9*sqrt(83) + 82)^(1/3) + 1)^2 - 6

1/27*((9*sqrt(83) + 82)^(1/3) + 1/(9*sqrt(83) + 82)^(1/3) + 1)^3 - 1/9*((9*sqrt(83) + 82)^(1/3) + 1/(9*sqrt(83) + 82)^(1/3) + 1)^2 - 6

_.simplify_full()

f (N (x1))

-1.77635683940025e-15

-1.77635683940025e-15

Rješenje 2. zadatka za zadaću

Neka je $f(x) = x^6 -2x^2 +x - 1$ . Pokušajte, pomoću funkcije , riješiti jednadžbu $f(x) = 0$ .

Pretvorite $f$ u polinom nad skupom realnih brojeva i odredite mu realne nul–točke. Izdvojite zadnje realno rješenje pa provjerite da je to zaista nul–točka.

Pretvorite $f$ u polinom nad skupom kompleksnih brojeva i odredite mu sve nul–točke. Izdvojite zadnje rješenje koje nije realno pa provjerite da je to zaista nul–točka.

Definicija simboličkog izraza i pokušaj primjene funkcije solve():

f(x) = x^6 - 2*x^2 + x - 1
solve (f(x) == 0, x)

[0 == x^6 - 2*x^2 + x - 1]

[0 == x^6 - 2*x^2 + x - 1]

Jednadžba nije riješena.

Pretvaranje izraza u polinom nad $\mathbb{R}$ i traženje realnih nul–točaka:

polr = f.polynomial(RR)
rjr = polr.roots()
rjr

[(-1.34713045310087, 1), (1.17027798065852, 1)]

[(-1.34713045310087, 1), (1.17027798065852, 1)]

xr1 = rjr[1][0]
xr1

1.17027798065852

1.17027798065852

polr (xr1)

0.000000000000000

0.000000000000000

Pretvaranje izraza u polinom nad $\mathbb{C}$ i traženje svih nul–točaka:

polc = f.polynomial(CC)
rjc = polc.roots()
rjc

[(-1.34713045310087, 1),
 (1.17027798065852, 1),
 (-0.187427396466431 - 1.14314681312089*I, 1),
 (-0.187427396466431 + 1.14314681312089*I, 1),
 (0.275853632687603 - 0.629757988522308*I, 1),
 (0.275853632687603 + 0.629757988522308*I, 1)]

[(-1.34713045310087, 1),
 (1.17027798065852, 1),
 (-0.187427396466431 - 1.14314681312089*I, 1),
 (-0.187427396466431 + 1.14314681312089*I, 1),
 (0.275853632687603 - 0.629757988522308*I, 1),
 (0.275853632687603 + 0.629757988522308*I, 1)]

len(rjc)

xc1 = rjc[5][0];
xc1

0.275853632687603 + 0.629757988522308*I

0.275853632687603 + 0.629757988522308*I

polc (xc1)

-2.22044604925031e-16

-2.22044604925031e-16

3. zadatak za zadaću

Numerički odredite nul–točku funkcije $f(x) = x^2 - 2 + \mathrm{ln}\,x$ .

Uputa: nacrtajte graf za $x\in[0, 2]$ .

f(x) =  x^2 - 2 + log(x)

plot (f, 0, 2)

rj = find_root( f(x), 1, 1.5)
rj

1.3140968043349732

1.3140968043349732

f (rj)

0.0

0.0

Rješenje 4. zadatka za zadaću

Riješite sustav

$-x + 2y +3z \,=\, 8$

$3x - y - z \,=\, -3$

$3x -3 y + 2 z \,=\,1$ .

Koliko iznosi numerička vrijednost varijable $z$ u rješenju? Koliko smo rješenja dobili?

Ako je rješenje jedinstveno, riješite sustav prevođenjem u matrični oblik (s komponentama u skupu $\mathbb{Q}$ ).

var ('x y z')
rj = solve ( [ -x + 2*y + 3*z == 8, 
               3*x - y - z == -3, 
               3*x - 3*y + 2*z == 1 ], 
             [x, y, z] )
rj

[[x == 0, y == 1, z == 2]]

[[x == 0, y == 1, z == 2]]

rj[0][2].right()

Dobili smo jedno rješenje, to jest, rješenje je jedinstveno.

A = matrix (QQ, 3, 3, [-1, 2, 3, 3, -1, -1, 3, -3, 2])
b = vector (QQ, [8, -3, 1])
x = A\b
x

(0, 1, 2)

(0, 1, 2)

Provjera (aritmetika je racionalna, a ne „realna”, pa smijemo ispitati jednakost):

A*x == b

True

True

reset ('x')

Rješenje 5. zadatka za zadaću

Odredite na kojemu podskupu skupa $\mathbb{R}$ funkcija $f : x \mapsto 4\,x^3 - 8\,x^2 - 4\,x + 8$ poprima manje vrijednosti od funkcije $g : x \mapsto \dfrac{1}{x}$ .

f(x) = 4*x^3 - 8*x^2 - 4*x + 8
g(x) = 1/x
solve (f(x) < g(x), x)

[[x < -1.038841807909604],
 [x > 0, x < 0.1367287331142753],
 [x > 0.8632712668857248, x < 2.038841807909605]]

[[x < -1.038841807909604],
 [x > 0, x < 0.1367287331142753],
 [x > 0.8632712668857248, x < 2.038841807909605]]

Traženi je skup $(-\infty; -1,\!038\,841\,807\,909\,604) \cup (0; 0,\!136\,728\,733\,114\,275\,3) \cup (0,\!863\,271\,266\,885\,724\,8; 2,\!038\,841\,807\,909\,605)$ ; rubovi intervalâ (osim $0$ i $-\infty$ ) približne su — pseudorealne — vrijednosti.

p1 = plot (f, -1.5, 2.5)
p2 = plot (g, -1.5, 2.5, ymin = -10, ymax = 10, color = 'green', detect_poles = True)
p1 + p2

MPZI_vj06_s_izradom

2447 days ago by fresl