NS_BEg_vl -- Sage

%auto
implicit_multiplication (True)

var ('P q0 l E J h')

$\newcommand{\Bold}[1]{\mathbf{#1}}\left(P, q_{0}, l, E, J, h\right)$

var ('a0 a1 a2 a3')

$\newcommand{\Bold}[1]{\mathbf{#1}}\left(a_{0}, a_{1}, a_{2}, a_{3}\right)$

w(x) = a0 + a1 x + a2 sinh (h/l x) + a3 cosh (h/l x) - (q0 l^2)/(2 E J h^2) * x^2
w

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ a_{1} x + a_{3} \cosh\left(\frac{h x}{l}\right) + a_{2} \sinh\left(\frac{h x}{l}\right) + a_{0} - \frac{l^{2} q_{0} x^{2}}{2 \, E J h^{2}}$

w1(x) = diff (w(x), x)
w1

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ \frac{a_{2} h \cosh\left(\frac{h x}{l}\right)}{l} + \frac{a_{3} h \sinh\left(\frac{h x}{l}\right)}{l} + a_{1} - \frac{l^{2} q_{0} x}{E J h^{2}}$

w2(x) = diff (w(x), x, 2)
w2

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ \frac{a_{3} h^{2} \cosh\left(\frac{h x}{l}\right)}{l^{2}} + \frac{a_{2} h^{2} \sinh\left(\frac{h x}{l}\right)}{l^{2}} - \frac{l^{2} q_{0}}{E J h^{2}}$

w(0) == 0

$\newcommand{\Bold}[1]{\mathbf{#1}}a_{0} + a_{3} = 0$

w1(0) == 0

$\newcommand{\Bold}[1]{\mathbf{#1}}a_{1} + \frac{a_{2} h}{l} = 0$

w(l) == 0

$\newcommand{\Bold}[1]{\mathbf{#1}}a_{1} l + a_{3} \cosh\left(h\right) + a_{2} \sinh\left(h\right) + a_{0} - \frac{l^{4} q_{0}}{2 \, E J h^{2}} = 0$

w1(l) == 0

$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{a_{2} h \cosh\left(h\right)}{l} + \frac{a_{3} h \sinh\left(h\right)}{l} + a_{1} - \frac{l^{3} q_{0}}{E J h^{2}} = 0$

aa = solve ([w(0) == 0, 
             w1(0) == 0, 
             w(l) == 0, 
             w1(l) == 0], 
            [a0, a1, a2, a3])

aa[0][0]

$\newcommand{\Bold}[1]{\mathbf{#1}}a_{0} = -\frac{{\left(h q_{0} {\left(\cosh\left(h\right) + 1\right)} - 2 \, q_{0} \sinh\left(h\right)\right)} l^{4}}{2 \, {\left(E J h^{4} \sinh\left(h\right) + {\left(E J \cosh\left(h\right)^{2} - E J \sinh\left(h\right)^{2} - 2 \, E J \cosh\left(h\right) + E J\right)} h^{3}\right)}}$

aa0 = (aa[0][0]).rhs().simplify_full()
aa0

$\newcommand{\Bold}[1]{\mathbf{#1}}-\frac{{\left(h \cosh\left(h\right) + h - 2 \, \sinh\left(h\right)\right)} l^{4} q_{0}}{2 \, {\left(E J h^{4} \sinh\left(h\right) - 2 \, E J h^{3} \cosh\left(h\right) + 2 \, E J h^{3}\right)}}$

((h*cosh(h) + h - 2*sinh(h))/(h*sinh(h) - 2*cosh(h) + 2)).simplify_trig()

$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{h \cosh\left(h\right) + h - 2 \, \sinh\left(h\right)}{h \sinh\left(h\right) - 2 \, \cosh\left(h\right) + 2}$

aa0_2h = ((h*cosh(h) + h - 2*sinh(h))/(h*sinh(h) - 2*cosh(h) + 2)).subs (h = 2*h)
aa0_2h

$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{h \cosh\left(2 \, h\right) + h - \sinh\left(2 \, h\right)}{h \sinh\left(2 \, h\right) - \cosh\left(2 \, h\right) + 1}$

aa0_2h.simplify_trig()

$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{\cosh\left(h\right)}{\sinh\left(h\right)}$

aa0 = -(q0 l^4)/(2 E J h^3) * coth (h/2)
aa0

$\newcommand{\Bold}[1]{\mathbf{#1}}-\frac{l^{4} q_{0} \coth\left(\frac{1}{2} \, h\right)}{2 \, E J h^{3}}$

aa[0][1]

$\newcommand{\Bold}[1]{\mathbf{#1}}a_{1} = \frac{{\left(h q_{0} \sinh\left(h\right) - 2 \, q_{0} {\left(\cosh\left(h\right) - 1\right)}\right)} l^{3}}{2 \, {\left(E J h^{3} \sinh\left(h\right) + {\left(E J \cosh\left(h\right)^{2} - E J \sinh\left(h\right)^{2} - 2 \, E J \cosh\left(h\right) + E J\right)} h^{2}\right)}}$

aa1 = (aa[0][1]).rhs().simplify_full()
aa1

$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{l^{3} q_{0}}{2 \, E J h^{2}}$

aa[0][2]

$\newcommand{\Bold}[1]{\mathbf{#1}}a_{2} = -\frac{{\left(h q_{0} \sinh\left(h\right) - 2 \, q_{0} {\left(\cosh\left(h\right) - 1\right)}\right)} l^{4}}{2 \, {\left(E J h^{4} \sinh\left(h\right) + {\left(E J \cosh\left(h\right)^{2} - E J \sinh\left(h\right)^{2} - 2 \, E J \cosh\left(h\right) + E J\right)} h^{3}\right)}}$

aa2 = (aa[0][2]).rhs().simplify_full()
aa2

$\newcommand{\Bold}[1]{\mathbf{#1}}-\frac{l^{4} q_{0}}{2 \, E J h^{3}}$

aa[0][3]

$\newcommand{\Bold}[1]{\mathbf{#1}}a_{3} = \frac{{\left(h q_{0} {\left(\cosh\left(h\right) + 1\right)} - 2 \, q_{0} \sinh\left(h\right)\right)} l^{4}}{2 \, {\left(E J h^{4} \sinh\left(h\right) + {\left(E J \cosh\left(h\right)^{2} - E J \sinh\left(h\right)^{2} - 2 \, E J \cosh\left(h\right) + E J\right)} h^{3}\right)}}$

aa3 = (aa[0][3]).rhs().simplify_full()
aa3

$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{{\left(h \cosh\left(h\right) + h - 2 \, \sinh\left(h\right)\right)} l^{4} q_{0}}{2 \, {\left(E J h^{4} \sinh\left(h\right) - 2 \, E J h^{3} \cosh\left(h\right) + 2 \, E J h^{3}\right)}}$

aa3 = -aa0
aa3

$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{l^{4} q_{0} \coth\left(\frac{1}{2} \, h\right)}{2 \, E J h^{3}}$

wa = w.subs (a0 = aa0, a1 = aa1, a2 = aa2, a3 = aa3)
wa

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ \frac{l^{4} q_{0} \cosh\left(\frac{h x}{l}\right) \coth\left(\frac{1}{2} \, h\right)}{2 \, E J h^{3}} + \frac{l^{3} q_{0} x}{2 \, E J h^{2}} - \frac{l^{2} q_{0} x^{2}}{2 \, E J h^{2}} - \frac{l^{4} q_{0} \coth\left(\frac{1}{2} \, h\right)}{2 \, E J h^{3}} - \frac{l^{4} q_{0} \sinh\left(\frac{h x}{l}\right)}{2 \, E J h^{3}}$

wp = wa.subs (h = l sqrt (P/(E J)))
wp

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ \frac{l q_{0} x}{2 \, P} - \frac{q_{0} x^{2}}{2 \, P} + \frac{l q_{0} \cosh\left(x \sqrt{\frac{P}{E J}}\right) \coth\left(\frac{1}{2} \, l \sqrt{\frac{P}{E J}}\right)}{2 \, E J \left(\frac{P}{E J}\right)^{\frac{3}{2}}} - \frac{l q_{0} \coth\left(\frac{1}{2} \, l \sqrt{\frac{P}{E J}}\right)}{2 \, E J \left(\frac{P}{E J}\right)^{\frac{3}{2}}} - \frac{l q_{0} \sinh\left(x \sqrt{\frac{P}{E J}}\right)}{2 \, E J \left(\frac{P}{E J}\right)^{\frac{3}{2}}}$

wp0 = wp.subs (l = 5, q0 = 50, E = 30000000, J = (3/10)^4/12, P = 2500)
wp0

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ \frac{9}{200} \, \sqrt{10} \cosh\left(\frac{1}{9} \, \sqrt{10} x\right) \coth\left(\frac{5}{18} \, \sqrt{10}\right) - \frac{1}{100} \, x^{2} - \frac{9}{200} \, \sqrt{10} \coth\left(\frac{5}{18} \, \sqrt{10}\right) - \frac{9}{200} \, \sqrt{10} \sinh\left(\frac{1}{9} \, \sqrt{10} x\right) + \frac{1}{20} \, x$

N (wp0(2.5))

$\newcommand{\Bold}[1]{\mathbf{#1}}0.00373114122928950$

# tlačna sila (radni list NS_BEg_tl)
# N (wp0(2.5)) == 0.00435513114356019

pw0 = plot (-wp0, 0., 5., aspect_ratio = 500)
pw0

M(x) = -E*J*w2(x)

Ma = M.subs (a2 = aa2, a3 = aa3)
Ma

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ -\frac{1}{2} \, {\left(\frac{l^{2} q_{0} \cosh\left(\frac{h x}{l}\right) \coth\left(\frac{1}{2} \, h\right)}{E J h} - \frac{l^{2} q_{0} \sinh\left(\frac{h x}{l}\right)}{E J h} - \frac{2 \, l^{2} q_{0}}{E J h^{2}}\right)} E J$

w2p0(x) = diff (wp0(x), x, 2)
w2p0(x)

$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{180} \, \sqrt{10} \cosh\left(\frac{1}{9} \, \sqrt{10} x\right) \coth\left(\frac{5}{18} \, \sqrt{10}\right) - \frac{1}{180} \, \sqrt{10} \sinh\left(\frac{1}{9} \, \sqrt{10} x\right) - \frac{1}{50}$

Mp0(x) = -E*J*w2p0(x)
Mp0 = Mp0.subs (E = 30000000, J = (3/10)^4/12)
Mp0

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ -\frac{225}{2} \, \sqrt{10} \cosh\left(\frac{1}{9} \, \sqrt{10} x\right) \coth\left(\frac{5}{18} \, \sqrt{10}\right) + \frac{225}{2} \, \sqrt{10} \sinh\left(\frac{1}{9} \, \sqrt{10} x\right) + 405$

N (Mp0(0.))

$\newcommand{\Bold}[1]{\mathbf{#1}}-99.1738783309783$

N (Mp0(5.))

$\newcommand{\Bold}[1]{\mathbf{#1}}-99.1738783309784$

N (Mp0(2.5))

$\newcommand{\Bold}[1]{\mathbf{#1}}47.7482685957980$

# tlačna sila 
# N (Mp0(2.5)) == 57.1860756495529

pm0 = plot (-Mp0, 0., 5., aspect_ratio = 1/62.5)
pm0

wl4(x) = q0 / (E J)

var ('C0 C1 C2 C3')

$\newcommand{\Bold}[1]{\mathbf{#1}}\left(C_{0}, C_{1}, C_{2}, C_{3}\right)$

wl3(x) = integrate (wl4, x) + C0
wl3

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ C_{0} + \frac{q_{0} x}{E J}$

wl2(x) = integrate (wl3, x) + C1
wl2

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ C_{0} x + C_{1} + \frac{q_{0} x^{2}}{2 \, E J}$

wl1(x) = integrate (wl2, x) + C2
wl1

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ \frac{1}{2} \, C_{0} x^{2} + C_{1} x + \frac{q_{0} x^{3}}{6 \, E J} + C_{2}$

wl0(x) = integrate (wl1, x) + C3
wl0

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ \frac{1}{6} \, C_{0} x^{3} + \frac{1}{2} \, C_{1} x^{2} + \frac{q_{0} x^{4}}{24 \, E J} + C_{2} x + C_{3}$

bb = solve ([wl0(0) == 0, 
             wl1(0) == 0, 
             wl0(l) == 0, 
             wl1(l) == 0], 
            [C0, C1, C2, C3])

wl(x) = wl0(x).subs (bb[0]).simplify_full()
wl

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ \frac{l^{2} q_{0} x^{2} - 2 \, l q_{0} x^{3} + q_{0} x^{4}}{24 \, E J}$

wl(x) = q0 / (24 E J) * (l^2 x^2 - 2 l x^3 + x^4)
wl

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ \frac{{\left(l^{2} x^{2} - 2 \, l x^{3} + x^{4}\right)} q_{0}}{24 \, E J}$

wl0 = wl.subs (l = 5, q0 = 50, E = 30000000, J = (3/10)^4/12)
wl0

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ \frac{1}{9720} \, x^{4} - \frac{1}{972} \, x^{3} + \frac{5}{1944} \, x^{2}$

wl0 (2.5)

$\newcommand{\Bold}[1]{\mathbf{#1}}0.00401877572016461$

pwl0 = plot (-wl0, 0., 5., aspect_ratio = 500, color = 'green')
pwl0

pw0 + pwl0

wl2_0(x) = diff (wl0, x, 2)
wl2_0

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ \frac{1}{810} \, x^{2} - \frac{1}{162} \, x + \frac{5}{972}$

Ml0(x) = -E*J*wl2_0 (x)
Ml0 = Ml0.subs (E = 30000000, J = (3/10)^4/12)
Ml0

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ -25 \, x^{2} + 125 \, x - \frac{625}{6}$

pml0 = plot (-Ml0, 0., 5., aspect_ratio = 1/62.5, color = 'green')
pml0

pm0 + pml0

NS_BEg_vl

1008 days ago by fresl