MPZI_vj02_s_izradom -- Sage

(„Lijepi” ispis svih rezultata, bez poziva funkcije show(), možete dobiti tako da na vrhu radnog lista označite kvadratić kraj riječi Typeset.)

Izrazi, funkcije, polinomi i njihovi grafovi

Simbolički izrazi

1. zadatak

Definirajte simbolički izraz $\mathtt{ex1} = 3x^3 + 18x^2 +9x -30$ pa zatim

izračunajte vrijednost $\mathtt{ex1}$ za $x=2$,
rastavite $\mathtt{ex1}$ na faktore,
dobivene faktore pomnožite (razvijte izraz dobiven faktorizacijom) i provjerite jeste li ponovo dobili $\mathtt{ex1}$,
zamijenite u $\mathtt{ex1}$ varijablu $x$ sa $x^2+1$,
novodobiveni izraz razvijte pa rastavite na faktore.

Definicija i račun za $x=2$:

ex1 = 3*x^3 + 18*x^2 + 9*x - 30
ex1

$\newcommand{\Bold}[1]{\mathbf{#1}}3 \, x^{3} + 18 \, x^{2} + 9 \, x - 30$

ex1 (x=2)

$\newcommand{\Bold}[1]{\mathbf{#1}}84$

ex1.subs (x=2)

$\newcommand{\Bold}[1]{\mathbf{#1}}84$

Faktorizacija i razvoj:

ex2 = ex1.factor()
ex2

$\newcommand{\Bold}[1]{\mathbf{#1}}3 \, {\left(x + 5\right)} {\left(x + 2\right)} {\left(x - 1\right)}$

ex2.expand()

$\newcommand{\Bold}[1]{\mathbf{#1}}3 \, x^{3} + 18 \, x^{2} + 9 \, x - 30$

ex2.expand() == ex1

$\newcommand{\Bold}[1]{\mathbf{#1}}3 \, x^{3} + 18 \, x^{2} + 9 \, x - 30 = 3 \, x^{3} + 18 \, x^{2} + 9 \, x - 30$

bool (ex2.expand() == ex1)

$\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{True}$

Zamjena $x$ sa $x^2+1$, razvoj i faktorizacija:

ex1.subs (x = x^2+1)

$\newcommand{\Bold}[1]{\mathbf{#1}}3 \, {\left(x^{2} + 1\right)}^{3} + 18 \, {\left(x^{2} + 1\right)}^{2} + 9 \, x^{2} - 21$

_.expand()

$\newcommand{\Bold}[1]{\mathbf{#1}}3 \, x^{6} + 27 \, x^{4} + 54 \, x^{2}$

_.factor()

$\newcommand{\Bold}[1]{\mathbf{#1}}3 \, {\left(x^{2} + 6\right)} {\left(x^{2} + 3\right)} x^{2}$

2. zadatak

Sage ne rastavlja svaki simbolički izraz koji je polinom na faktore. Pokušajte, na primjer, izraz $\mathtt{ex} = 3x^5-4x^3+3$ rastaviti na faktore. U dijelu posvećenom polinomina, u ovom radnom listu, bit će prikazano kako se ovakav izraz ipak može rastaviti.

ex = 3*x^5 - 4*x^3 + 3 
ex.factor()

$\newcommand{\Bold}[1]{\mathbf{#1}}3 \, x^{5} - 4 \, x^{3} + 3$

3. zadatak

Definirajte simbolički izraz $\displaystyle \mathtt{ex} = \sin \left(x + \frac{n\pi}{2}\right)$ pa zatim

pojednostavnite $\mathtt{ex}$ primjenom funkcije expand_trig(),
u dobivenom izrazu provedite zamjenu $x=0$ i rezultat označite s $\mathtt{ex1}$,
izraz $\mathtt{ex1}$ izračunajte za parne i za neparne vrijednosti broja $n$.

Definiranje izraza:

var ('n')
ex = sin (x+(n*pi)/2)
ex

$\newcommand{\Bold}[1]{\mathbf{#1}}\sin\left(\frac{1}{2} \, \pi n + x\right)$

Pojednostavnjenje pomoću .expand_trig() i zamjena x s 0:

ex1 = ex.expand_trig()
ex1

$\newcommand{\Bold}[1]{\mathbf{#1}}\cos\left(x\right) \sin\left(\frac{1}{2} \, \pi n\right) + \cos\left(\frac{1}{2} \, \pi n\right) \sin\left(x\right)$

ex1 = ex1.subs(x=0)
ex1

$\newcommand{\Bold}[1]{\mathbf{#1}}\sin\left(\frac{1}{2} \, \pi n\right)$

Račun za parne $n$:

assume (n, 'even')
ex1

$\newcommand{\Bold}[1]{\mathbf{#1}}\sin\left(\frac{1}{2} \, \pi n\right)$

ex1.simplify_full()

$\newcommand{\Bold}[1]{\mathbf{#1}}0$

Za neparni $n$ izraz $\displaystyle \sin\frac{n\pi}{2}$ je jednak $+1$ ili $-1$ i to prema sljedećem pravilu: neka je $n=2k+1$; tada je

$\displaystyle \sin\frac{(2k+1)\pi}{2} = \left\{ \begin{array}{rcl} 1& \mathrm{za} & k \;\; \mathrm{paran}\;\; \mathrm{ili}\;\; 0 \\ -1& \mathrm{za} & k \;\; \mathrm{neparan} \end{array} \right. $

Takav rezultat Sage ne zna zapisati:

forget (n, 'even')
assume (n, 'odd')
ex1.expand_trig()

$\newcommand{\Bold}[1]{\mathbf{#1}}\sin\left(\frac{1}{2} \, \pi n\right)$

Pojedinačne vrijednosti za $n$ daju ispravan rezultat:

sin ((2*2+1)*pi/2)

$\newcommand{\Bold}[1]{\mathbf{#1}}1$

ili:

ex1.subs (n = 2*2+1)

$\newcommand{\Bold}[1]{\mathbf{#1}}1$

sin ((2*3+1)*pi/2)

$\newcommand{\Bold}[1]{\mathbf{#1}}-1$

ili:

ex1.subs (n = 2*3+1)

$\newcommand{\Bold}[1]{\mathbf{#1}}-1$

Naravno, zadatak možemo riješiti i tako da $\displaystyle \sin\frac{n\pi}{2}$ napišemo u obliku $\displaystyle \sin\frac{(2k+1)\pi}{2}$, pa taj izraz pojednostavnimo uz odgovarajuće pretpostavke o $k$:

var ('k')
ex1n = ex1.subs (n = 2*k+1)
ex1n

$\newcommand{\Bold}[1]{\mathbf{#1}}\sin\left(\frac{1}{2} \, \pi + \pi k\right)$

forget()
assume (k, 'odd')
ex1n.simplify_full ()

$\newcommand{\Bold}[1]{\mathbf{#1}}-1$

forget()
assume (k, 'even')
ex1n.simplify_full ()

$\newcommand{\Bold}[1]{\mathbf{#1}}1$

1. zadatak za zadaću

Neka je $\mathtt{ex} = 2x^5 - 4x^4 - 2x + 4$.

Izračunajte $\mathtt{ex}$ za $x = 1,\!5$.
Rastavite $\mathtt{ex}$ na faktore.
Razvijte izraz dobiven faktorizacijom (pomnožite dobivene faktore).
U $\mathtt{ex}$ zamijenite $x$ s $2x^2+3$ pa novodobiveni izraz rastavite na faktore.

Rješenja su pri kraju radnog lista.

2. zadatak za zadaću

Neka je $\mathtt{ex} = \ln(e\cdot x)+ \mathrm{tg}(x-1+n\cdot \pi\cdot x)$.

Pojednostavnite izraz $\mathtt{ex}$ naredbom simplify_full().
Izračunajte $\mathtt{ex}$ za $x=1$. Potom pretpostavite da je broj $n$ cijeli pa ponovo izračunajte $\mathtt{ex}$ za $x=1$.

Definicija funkcije i graf funkcije

Funkcija plot()

Eksplicitno zadana krivulja je krivulja zadana izrazom oblika $y=f(x)$.

Crtanje eksplicitno zadanih krivulja u ravnini izvodi se funkcijom plot(). Oblik poziva je

plot (funkcija, (varijabla, donja_granica, gornja_granica), opcije...)

ili

plot (funkcija, donja_granica_varijable, gornja_granica_varijable, opcije...)

Najvažnije su opcije:

plot_points — (podrazumijeva se: 200) broj točaka koje će se upotrebiti za crtanje grafa,
ymin — početna vrijednost varijable y u slici,
ymax — završna vrijednost varijable y u slici,
linestyle — način crtanja linije:
- '-' ili 'solid' — puna linija (podrazumijeva se),
- ':' ili 'dotted' — točkasto,
- '--' ili 'dashed' — crtano,
- '-.' ili 'dashdot' — crta–točka,
- ' ' (razmak) ili 'None' — ništa,
color — tekstom (nizom znakova) zadano ime boje, npr. 'cyan', ili trojka brojeva koja zadaje boju RGB podacima,
detect_poles — (podrazumijeva se: False) ako se postavi na True, polovi će biti pronađeni, a ako se postavi na 'show' bit će nacrtane i vertikalne asimptote,
fill — (podrazumijeva se: False) ako se postavi na True, područje između grafa i osi $x$ bit će osjenčeno,
figsize — (podrazumijeva se: 8) veličina slike, upola manji broj znači, približno, upola manju sliku,
axes — (podrazumijeva se: True) ako se postavi na False, osi koordinatnog sustava neće biti nacrtane,
axes_labels — nazivi osi, zadaje se u obliku ['naziv_x_osi', 'naziv_y-osi'] ili ('naziv_x_osi', 'naziv_y-osi'),
frame — (podrazumijeva se: False) ako se postavi na True, oko slike će biti nacrtan okvir,
aspect_ratio — omjer duljina jediničnih dužina na osima $y$ i $x$ (omjer visine i širine pravokutnika koji će biti prikazan kao kvadrat),
legend_label — oznaka krivulje na slici; zadaje se kao tekst (niz znakova),
thickness — (podrazumijeva se: 1) debljina linije.

4. zadatak

Definirajte funkciju $\displaystyle f(x)=\frac{x}{x^2-1}$.
Izračunajte vrijednost i približnu vrijednost funkcije $f$ u točki $\displaystyle x=\frac{\sqrt{3}}{\ln 5}$.
Nacrtajte graf funkcije $f$ nad intervalom $[-6,6]$, a zatim, upotrebom opcija ymin i ymax, ograničite $y$ tako da vrijedi $-1,\!5 < y < 1,\!5$. Opcijom thickness postavite debljinu linije na 4.

var ('x');
f(x) = x / (x^2-1)

y = f (sqrt(3)/log(5))
y

$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{\sqrt{3}}{{\left(\frac{3}{\log\left(5\right)^{2}} - 1\right)} \log\left(5\right)}$

N (y)

$\newcommand{\Bold}[1]{\mathbf{#1}}6.80391231986142$

plot ( f(x), (x, -6, 6) )

plot ( f(x), (x, -6, 6), detect_poles = True )

plot ( f(x), (x, -6, 6), ymin = -1.5, ymax = 1.5, thickness = 4, detect_poles = 'show' )

3. zadatak za zadaću

Definirajte funkciju $g(x)=x+\sin x$.
Odredite je li $|g(1,\!2)|$ veće od $|g(-2,\!1)|$
Nacrtajte graf funkcije $g$ nad intervalom $[-8,8]$ pomoću naredbe plot(). Neka veličina slike bude 5.
Primjenom odgovarajućih opcija uredite sliku tako da je omjer jedinica na osima $y$ i $x$ jednak 1/6, imenujte osi $x$ i $y$, a graf neka bude crvene boje, nacrtan točkasto.

5. zadatak

Na istoj slici nacrtajte grafove funkcija $\sin\!x$, $\sin\frac{x}{2}$ i $\sin2x$ nad intervalom $[0,2\pi]$. Obojite ih redom crveno, plavo i zeleno. Nacrtajte iste grafove na novoj slici tako da se osi ne prikazuju.

p1 = plot (sin(x), (x, 0, 2*pi), color = "red")
p2 = plot (sin(x/2), (x, 0, 2*pi), color = "blue")
p3 = plot (sin(2*x), (x, 0, 2*pi), color = "green")

p1 + p2 + p3

(p1 + p2 + p3).show (axes = false)

ili

show (p1+p2+p3, axes = false)

Polinomi

6. zadatak

Simbolički izraz $\mathtt{ex} = 3x^5-4x^3+3$ (iz zadatka br. 2) transformirajte tako da Sage zna da je to polinom nad skupom realnih brojeva. Polinom potom rastavite na faktore. Nakon toga konvertirajte $\mathtt{ex}$ u polinom nad skupom kompleksnih brojeva te ga rastavite na faktore.

ex = 3*x^5 - 4*x^3 + 3
ex

$\newcommand{\Bold}[1]{\mathbf{#1}}3 \, x^{5} - 4 \, x^{3} + 3$

poli = ex.polynomial (RR)
poli

$\newcommand{\Bold}[1]{\mathbf{#1}}3.00000000000000 x^{5} + 0.000000000000000 x^{4} - 4.00000000000000 x^{3} + 0.000000000000000 x^{2} + 0.000000000000000 x + 3.00000000000000$

poli.factor()

$\newcommand{\Bold}[1]{\mathbf{#1}}\left(3.00000000000000\right) \cdot (x + 1.32709626560972) \cdot (x^{2} - 2.00876050035395 x + 1.13076828743849) \cdot (x^{2} + 0.681664234744229 x + 0.666383066681653)$

poli1 = ex.polynomial (CC)
poli1

$\newcommand{\Bold}[1]{\mathbf{#1}}3.00000000000000 x^{5} + 0.000000000000000 x^{4} - 4.00000000000000 x^{3} + 0.000000000000000 x^{2} + 0.000000000000000 x + 3.00000000000000$

poli1.factor()

$\newcommand{\Bold}[1]{\mathbf{#1}}\left(3.00000000000000\right) \cdot (x - 1.00438025017697 - 0.349268665203344i) \cdot (x - 1.00438025017697 + 0.349268665203344i) \cdot (x + 0.340832117372114 - 0.741765821839544i) \cdot (x + 0.340832117372114 + 0.741765821839544i) \cdot (x + 1.32709626560972)$

Napomena: Polinom $p(x) = 3x^5-4x^3+3$ ima jednu realnu nul-točku ($x_0 \simeq -1,\!327\,096$) i dva para konjugiranokompleksnih nul-točaka:

plot (poli, -2, 2, ymin = -1, ymax = 5)

7. zadatak

Definirajte dva simbolička izraza:

$\mathtt{ex1} = t^3-t^2-t-2$
$\mathtt{ex2} = t^4+t^3-4t-16$

pa ih pretvorite u polinome $\mathtt{pol1}$ i $\mathtt{pol2}$ nad skupom realnih brojeva.

Zatim:

izračunajte vrijednost polinoma $\mathtt{poli1}$ u točki $t=2,\!5$,
odredite zbroj i umnožak polinoma $\mathtt{poli1}$ i $\mathtt{poli2}$,
izračunajte kvocijent i ostatak dijeljena polinoma $\mathtt{poli2}$ polinomom $\mathtt{poli1}$,
rastavite polinom $\mathtt{poli2}$ na faktore (nad skupom realnih brojeva) pa dobivene faktore pomnožite (razvijte izraz dobiven faktorizacijom),
nacrtajte graf polinoma $\mathtt{poli2}$ za $t \in [-2,\!1;\, 2,\!1]$.

definiranje simboličkih izraza

var ('t')
ex1 = t^3 - t^2 - t - 2
ex1

$\newcommand{\Bold}[1]{\mathbf{#1}}t^{3} - t^{2} - t - 2$

ex2 = t^4 + t^3 -4*t - 16
ex2

$\newcommand{\Bold}[1]{\mathbf{#1}}t^{4} + t^{3} - 4 \, t - 16$

pretvaranje simboličkih izraza u polinome

poli1 = ex1.polynomial (RR)
poli1

$\newcommand{\Bold}[1]{\mathbf{#1}}t^{3} - t^{2} - t - 2.00000000000000$

poli2 = ex2.polynomial (RR)
poli2

$\newcommand{\Bold}[1]{\mathbf{#1}}t^{4} + t^{3} + 0.000000000000000 t^{2} - 4.00000000000000 t - 16.0000000000000$

računanje s polinomima

poli1 (2.5)

$\newcommand{\Bold}[1]{\mathbf{#1}}4.87500000000000$

poli1 + poli2

$\newcommand{\Bold}[1]{\mathbf{#1}}t^{4} + 2.00000000000000 t^{3} - t^{2} - 5.00000000000000 t - 18.0000000000000$

poli1 * poli2

$\newcommand{\Bold}[1]{\mathbf{#1}}t^{7} + 0.000000000000000 t^{6} - 2.00000000000000 t^{5} - 7.00000000000000 t^{4} - 14.0000000000000 t^{3} + 20.0000000000000 t^{2} + 24.0000000000000 t + 32.0000000000000$

poli2 / poli1

$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{t^{4} + t^{3} + 0.000000000000000 t^{2} - 4.00000000000000 t - 16.0000000000000}{t^{3} - t^{2} - t - 2.00000000000000}$

poli2 // poli1

$\newcommand{\Bold}[1]{\mathbf{#1}}t + 2.00000000000000$

poli2 % poli1

$\newcommand{\Bold}[1]{\mathbf{#1}}3.00000000000000 t^{2} + 0.000000000000000 t - 12.0000000000000$

(poli2 // poli1) * poli1 + poli2 % poli1 == poli2

$\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{True}$

faktoriziranje i razvoj

poli3 = poli2.factor()
poli3

$\newcommand{\Bold}[1]{\mathbf{#1}}(t - 2.00000000000000) \cdot (t + 2.00000000000000) \cdot (t^{2} + t + 4.00000000000000)$

poli3.expand()

$\newcommand{\Bold}[1]{\mathbf{#1}}t^{4} + t^{3} + 0.000000000000000 t^{2} - 4.00000000000000 t - 16.0000000000000$

crtanje grafa

plot (poli2, -2.1, 2.1)

Napomena: Polinom $p_2(t) = t^4+t^3-4t-16$ ima dvije realne nul-točke ($t_0 = -2$ i $t_1 = -2$) i jedan par konjugirano kompleksnih nul-točaka.

4. zadatak za zadaću

Definirajte dva izraza

$\mathtt{ex1} = v^4-1$
$\mathtt{ex2} = v^6+9v^4-v^2-9$

pa ih pretvorite u polinome $\mathtt{poli1}$ i $\mathtt{poli2}$ nad skupom realnih brojeva. Zatim:

izračunajte vrijednost polinoma $\mathtt{poli1}$ u točki $v=-1$,
odredite zbroj i umnožak polinoma $\mathtt{poli1}$ i $\mathtt{poli2}$,
izračunajte kvocijent i ostatak dijeljena polinoma $\mathtt{poli2}$ polinomom $\mathtt{poli1}$,
polinom $\mathtt{poli2}$ rastavite na faktore (nad skupom realnih brojeva) pa dobivene faktore pomnožite (razvijte izraz dobiven faktorizacijom),
izraz $\mathtt{ex2}$ pretvorite u polinom $\mathtt{poli3}$ nad kompleksnim brojevima pa ga faktorizirajte,
nacrtajte graf polinoma $\mathtt{poli2}$ za $v \in [-1,\!1;\, 1,\!1]$.

Rješenja 1. zadatka za zadaću

Neka je $\mathtt{ex} = 2x^5 - 4x^4 - 2x + 4$.

Izračunajte $\mathtt{ex}$ za $x = 1,\!5$,
Rastavite $\mathtt{ex}$ na faktore.
Razvijte izraz dobiven faktorizacijom (pomnožite dobivene faktore).
U $\mathtt{ex}$ zamijenite $x$ sa $2x^2+3$ pa novodobiveni izraz rastavite na faktore.

ex = 2*x^5 - 4*x^4 - 2*x + 4;
ex (x = 1.5)

$\newcommand{\Bold}[1]{\mathbf{#1}}-4.06250000000000$

ex.factor()

$\newcommand{\Bold}[1]{\mathbf{#1}}2 \, {\left(x^{2} + 1\right)} {\left(x + 1\right)} {\left(x - 1\right)} {\left(x - 2\right)}$

_.expand()

$\newcommand{\Bold}[1]{\mathbf{#1}}2 \, x^{5} - 4 \, x^{4} - 2 \, x + 4$

ex1 = ex.subs (x = 2*x^2 + 3)
ex1

$\newcommand{\Bold}[1]{\mathbf{#1}}2 \, {\left(2 \, x^{2} + 3\right)}^{5} - 4 \, {\left(2 \, x^{2} + 3\right)}^{4} - 4 \, x^{2} - 2$

ex1 = ex1.expand()
ex1

$\newcommand{\Bold}[1]{\mathbf{#1}}64 \, x^{10} + 416 \, x^{8} + 1056 \, x^{6} + 1296 \, x^{4} + 752 \, x^{2} + 160$

ex1.factor()

$\newcommand{\Bold}[1]{\mathbf{#1}}16 \, {\left(2 \, x^{4} + 6 \, x^{2} + 5\right)} {\left(2 \, x^{2} + 1\right)} {\left(x^{2} + 2\right)} {\left(x^{2} + 1\right)}$

Rješenja 2. zadatka za zadaću

Neka je $\mathtt{ex} = \ln(e\cdot x)+ \mathrm{tg}(x-1+n\cdot \pi\cdot x)$.

Pojednostavite izraz $\mathtt{ex}$ naredbom simplify_full().
Izračunajte $\mathtt{ex}$ za $x=1$. Potom pretpostavite da je broj $n$ cijeli pa ponovo izračunajte $\mathtt{ex}$ za $x=1$.

var('n')
ex = log (e*x) + tan (x - 1 + n*pi*x)
ex

$\newcommand{\Bold}[1]{\mathbf{#1}}\log\left(x e\right) + \tan\left(\pi n x + x - 1\right)$

ex1 = ex (x=1)
ex1

$\newcommand{\Bold}[1]{\mathbf{#1}}\tan\left(\pi n\right) + 1$

forget()
assume (n, 'integer')
ex1.simplify_full()

$\newcommand{\Bold}[1]{\mathbf{#1}}1$

Rješenja 3. zadatka za zadaću

Definirajte funkciju $g(x)=x+\sin x$.
Odredite da li je $|g(1,\!2)|$ veće od $|g(-2,\!1)|$.
Nacrtajte graf funkcije $g$ nad intervalom $[-8,8]$ pomoću funkcije plot(). Neka slika bude veličine 5.
Primjenom odgovarajućih opcija uredite sliku tako da je omjer jedinica na osima $y$ i $x$ jednak 1/6, imenujte osi $x$ i $y$, a graf neka bude crvene boje, nacrtan točkasto.

g(x) = x + sin(x)

abs (g (1.2)) > abs (g (-2.1))

$\newcommand{\Bold}[1]{\mathbf{#1}}2.13203908596723 > 2.96320936664887$

bool ( abs (g (1.2)) > abs (g (-2.1)) )

$\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{False}$

plot (g, (x, -8, 8), figsize = 5)

plot (g, (x, -8, 8), figsize = 5, aspect_ratio = 1/6, axes_labels = ("x-os", "y-os"), linestyle = ":", color="red")

Rješenja 4. zadatka za zadaću

Definirajte dva izraza

$\mathtt{ex1} = v^4-1$
$\mathtt{ex2} = v^6+9v^4-v^2-9$

pa ih pretvorite u polinome $\mathtt{poli1}$ i $\mathtt{poli2}$ nad skupom relanih brojeva. Zatim:

izračunajte vrijednost polinoma $\mathtt{poli1}$ u točki $v=-1$,
odredite zbroj i umnožak polinoma $\mathtt{poli1}$ i $\mathtt{poli2}$,
izračunajte kvocijent i ostatak dijeljena polinoma $\mathtt{poli2}$ polinomom $\mathtt{poli1}$,
polinom $\mathtt{poli2}$ rastavite na faktore (nad skupom realnih brojeva) pa dobivene faktore pomnožite (razvijte izraz dobiven faktorizacijom),
izraz $\mathtt{ex2}$ pretvorite u polinom $\mathtt{poli3}$ nad kompleksnim brojevima pa ga faktorizirajte,
nacrtajte graf polinoma $\mathtt{poli2}$ za $v \in [-1,\!1; 1,\!1]$.

var ('v')
ex1 = v^4 - 1
ex1

$\newcommand{\Bold}[1]{\mathbf{#1}}v^{4} - 1$

ex2 = v^6 + 9*v^4 - v^2 - 9
ex2

$\newcommand{\Bold}[1]{\mathbf{#1}}v^{6} + 9 \, v^{4} - v^{2} - 9$

poli1 = ex1.polynomial (RR)
poli1

$\newcommand{\Bold}[1]{\mathbf{#1}}v^{4} + 0.000000000000000 v^{3} + 0.000000000000000 v^{2} + 0.000000000000000 v - 1.00000000000000$

poli2 = ex2.polynomial (RR)
poli2

$\newcommand{\Bold}[1]{\mathbf{#1}}v^{6} + 0.000000000000000 v^{5} + 9.00000000000000 v^{4} + 0.000000000000000 v^{3} - v^{2} + 0.000000000000000 v - 9.00000000000000$

poli1 (-1)

$\newcommand{\Bold}[1]{\mathbf{#1}}0.000000000000000$

poli1 + poli2

$\newcommand{\Bold}[1]{\mathbf{#1}}v^{6} + 0.000000000000000 v^{5} + 10.0000000000000 v^{4} + 0.000000000000000 v^{3} - v^{2} + 0.000000000000000 v - 10.0000000000000$

poli1 * poli2

$\newcommand{\Bold}[1]{\mathbf{#1}}v^{10} + 0.000000000000000 v^{9} + 9.00000000000000 v^{8} + 0.000000000000000 v^{7} - 2.00000000000000 v^{6} + 0.000000000000000 v^{5} - 18.0000000000000 v^{4} + 0.000000000000000 v^{3} + v^{2} + 0.000000000000000 v + 9.00000000000000$

poli2 // poli1

$\newcommand{\Bold}[1]{\mathbf{#1}}v^{2} + 0.000000000000000 v + 9.00000000000000$

poli2 % poli1

$\newcommand{\Bold}[1]{\mathbf{#1}}0$

(poli2 // poli1) * poli1 + poli2 % poli1 == poli2

$\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{True}$

poli2f = poli2.factor()
poli2f

$\newcommand{\Bold}[1]{\mathbf{#1}}(v - 1.00000000000000) \cdot (v + 1.00000000000000) \cdot (v^{2} + 0.000000000000000 v + 1.00000000000000) \cdot (v^{2} + 0.000000000000000 v + 9.00000000000000)$

poli2f.expand()

$\newcommand{\Bold}[1]{\mathbf{#1}}v^{6} + 0.000000000000000 v^{5} + 9.00000000000000 v^{4} + 0.000000000000000 v^{3} - v^{2} + 0.000000000000000 v - 9.00000000000000$

poli3 = ex2.polynomial (CC)
poli3.factor()

$\newcommand{\Bold}[1]{\mathbf{#1}}(v - 1.00000000000000) \cdot (v - 3.00000000000000i) \cdot (v - 1.00000000000000i) \cdot (v + 1.00000000000000i) \cdot (v + 3.00000000000000i) \cdot (v + 1.00000000000000)$

poli2.plot (-1.1, 1.1)

Napomena: Polinom $p_2(v) = v^6+9v^4-v^2-9$ ima dvije realne nul-točke ($v_0 = -1$ i $v_1 = 1$) i dva para konjugirano kompleksnih nul-točaka.

MPZI_vj02_s_izradom

2544 days ago by fresl