MPZI_predavanje_06 -- Sage

Jednadžbe i nejednadžbe

Jednadžbe su relacijski izrazi koji sadrže dva aritmetička (pod)izraza povezana relacijskim operatorom $\mathtt{==}$ , dok su nejednadžbe relacijski izrazi koji sadrže dva aritmetička izraza povezana relacijskim operatorima $\mathtt{<}$ , $\mathtt{>}$ , $\mathtt{<=}$ i $\mathtt{>=}$ . (Aritmetičke ste izraze upoznali na drugom predavanju.) Izrazi koji ulaze u jednadžbe i nejednadžbe ponajčešće sadrže varijable koje se uzimaju za nepoznanice.

Izraz lijevo od relacijskoga operatora naziva se lijevom stranom (engl. left hand side, lhs), a izraz operatoru zdesna desnom stranom (engl. right hand side, rhs).

(sin (x) == x^2).left_hand_side()

sin(x)

sin(x)

(sin (x) == x^2).left()

sin(x)

sin(x)

(sin (x) == x^2).lhs()

sin(x)

sin(x)

(sin (x) == x^2).right_hand_side()

x^2

x^2

(sin (x) == x^2).right()

x^2

x^2

(sin (x) == x^2).rhs()

x^2

x^2

Nelinearne algebarske jednadžbe s jednom nepoznanicom

Jednadžbe oblika a == b, gdje su a i b aritmetički izrazi od kojih barem jedan sadrži varijablu x, možemo pisati u obliku a − b == 0. Definiramo li s pomoću izraza a − b funkciju f(x) = a − b, rješavanje jednadžbe a == b može se interpretirati i kao nalaženje nul–točaka funkcije f(): treba naći vrijednosti varijable x za koje je f(x) == 0. Nul–točke funkcije nazivamo i njezinim korijenima.

f(x) = x^4 - 3*x^2 + 4/3

plot (f, -9/5, 9/5, figsize = 5)

Za nalaženje točnih rješenja nelinearnih jednažbi s jednom nepoznanicom upotrebljava se funkcija solve():

solve (f(x) == 0, x)

[x == -sqrt(1/6*sqrt(33) + 3/2), x == sqrt(1/6*sqrt(33) + 3/2), x ==
-sqrt(-1/6*sqrt(33) + 3/2), x == sqrt(-1/6*sqrt(33) + 3/2)]

[x == -sqrt(1/6*sqrt(33) + 3/2), x == sqrt(1/6*sqrt(33) + 3/2), x == -sqrt(-1/6*sqrt(33) + 3/2), x == sqrt(-1/6*sqrt(33) + 3/2)]

show (_)

$\newcommand{\Bold}[1]{\mathbf{#1}}\left[x = -\sqrt{\frac{1}{6} \, \sqrt{33} + \frac{3}{2}}, x = \sqrt{\frac{1}{6} \, \sqrt{33} + \frac{3}{2}}, x = -\sqrt{-\frac{1}{6} \, \sqrt{33} + \frac{3}{2}}, x = \sqrt{-\frac{1}{6} \, \sqrt{33} + \frac{3}{2}}\right]$

Budući da nelinearne jednadžbe najčešće imaju više rješenja, ona su navedena u listi:

s = solve (f(x) == 0, x)

len (s)

show (s[0])

$\newcommand{\Bold}[1]{\mathbf{#1}}x = -\sqrt{\frac{1}{6} \, \sqrt{33} + \frac{3}{2}}$

show (s[3])

$\newcommand{\Bold}[1]{\mathbf{#1}}x = \sqrt{-\frac{1}{6} \, \sqrt{33} + \frac{3}{2}}$

Svaka je komponenta liste rješenja relacijski izraz s operatorom ==. Lijeva je strana izraza oznaka nepoznanice, a desna vrijednost rješenja:

s[0]

x == -sqrt(1/6*sqrt(33) + 3/2)

x == -sqrt(1/6*sqrt(33) + 3/2)

s[0].lhs()

s[0].rhs()

-sqrt(1/6*sqrt(33) + 3/2)

-sqrt(1/6*sqrt(33) + 3/2)

Rješenje možemo provjeriti uvrštavanjem:

f (s[0].rhs())

1/36*(sqrt(33) + 9)^2 - 1/2*sqrt(33) - 19/6

1/36*(sqrt(33) + 9)^2 - 1/2*sqrt(33) - 19/6

expand (_)

f (s[2].rhs())

1/36*(sqrt(33) - 9)^2 + 1/2*sqrt(33) - 19/6

1/36*(sqrt(33) - 9)^2 + 1/2*sqrt(33) - 19/6

expand (_)

Približne „realne” vrijednosti rješenja možemo, kao i uvijek, dobiti s pomoću funkcije N():

N (s[0].rhs())

-1.56761829147160

-1.56761829147160

N (s[1].rhs(), digits = 29)

1.5676182914715999542878182054

1.5676182914715999542878182054

N (s[2].rhs(), digits = 48)

-0.736595473950024953603231468788402628447700698803

-0.736595473950024953603231468788402628447700698803

N (s[3].rhs(), digits = 72)

0.736595473950024953603231468788402628447700698802725146229432535171117146

0.736595473950024953603231468788402628447700698802725146229432535171117146

... i „realna” se rješenja, naravno, mogu provjeriti, ali tada ne treba očekivati točno zadovoljenje jednadžbe:

f (N (s[0].rhs()))

-8.88178419700125e-16

-8.88178419700125e-16

f (N (s[1].rhs(), digits = 29))

6.3108872417680944432938285223e-30

6.3108872417680944432938285223e-30

f (N (s[2].rhs(), digits = 48))

-4.27642353614751303382485834744237100610431500817e-50

-4.27642353614751303382485834744237100610431500817e-50

f (N (s[3].rhs(), digits = 72))

-3.53737464016668451855824972300304366432911374927310085530570894138105520e-74

-3.53737464016668451855824972300304366432911374927310085530570894138105520e-74

Za polinome stupnja manjega od 5 nul–točke se uvijek mogu točno odrediti. Ako su koeficijenti polinoma cijeli ili racionalni brojevi, onda pod točnim rješenjem podrazumijevamo izraze koji sadrže samo cijele i racionalne brojeve i njihove cijele i racionalne potencije povezane aritmetičkim operatorima. Rješenja mogu biti i kompleksna, pri čemu rečeno vrijedi za realni i za imaginarni dio:

solve (x^3 - 1 == 0, x)

[x == 1/2*I*sqrt(3) - 1/2, x == -1/2*I*sqrt(3) - 1/2, x == 1]

[x == 1/2*I*sqrt(3) - 1/2, x == -1/2*I*sqrt(3) - 1/2, x == 1]

show (_)

$\newcommand{\Bold}[1]{\mathbf{#1}}\left[x = \frac{1}{2} i \, \sqrt{3} - \frac{1}{2}, x = -\frac{1}{2} i \, \sqrt{3} - \frac{1}{2}, x = 1\right]$

plot (x^3 - 1, -2, 2, figsize = 5)

Ako su koeficijenti polinoma zadani kao „realni” brojevi (u zapisu s točkom), SageMath će ih prešutno pretvoriti u racionalne brojeve:

solve (x^3 - 0.2 == 0, x)

[x == 1/10*5^(2/3)*(I*sqrt(3) - 1), x == 1/10*5^(2/3)*(-I*sqrt(3) - 1), x ==
1/5*5^(2/3)]

[x == 1/10*5^(2/3)*(I*sqrt(3) - 1), x == 1/10*5^(2/3)*(-I*sqrt(3) - 1), x == 1/5*5^(2/3)]

show (_)

$\newcommand{\Bold}[1]{\mathbf{#1}}\left[x = \frac{1}{10} \cdot 5^{\frac{2}{3}} {\left(i \, \sqrt{3} - 1\right)}, x = \frac{1}{10} \cdot 5^{\frac{2}{3}} {\left(-i \, \sqrt{3} - 1\right)}, x = \frac{1}{5} \cdot 5^{\frac{2}{3}}\right]$

solve (x^3 - 2e-1 == 0, x)

[x == 1/10*5^(2/3)*(I*sqrt(3) - 1), x == 1/10*5^(2/3)*(-I*sqrt(3) - 1), x ==
1/5*5^(2/3)]

[x == 1/10*5^(2/3)*(I*sqrt(3) - 1), x == 1/10*5^(2/3)*(-I*sqrt(3) - 1), x == 1/5*5^(2/3)]

show (_)

Koeficijenti polinoma mogu biti i funkcije cijelih i racionalnih brojeva:

f(x) = expand ((x + sqrt (1/2))^3 - sqrt (2))
show (f)

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ x^{3} + 3 \, \sqrt{\frac{1}{2}} x^{2} + \frac{3}{2} \, x - \sqrt{2} + \frac{1}{2} \, \sqrt{\frac{1}{2}}$

solve (f(x) == 0, x)

[x == -1/2*2^(1/6)*(I*sqrt(3) + 1) - 1/2*sqrt(2), x == -1/2*2^(1/6)*(-I*sqrt(3)
+ 1) - 1/2*sqrt(2), x == -1/2*sqrt(2) + 2^(1/6)]

[x == -1/2*2^(1/6)*(I*sqrt(3) + 1) - 1/2*sqrt(2), x == -1/2*2^(1/6)*(-I*sqrt(3) + 1) - 1/2*sqrt(2), x == -1/2*sqrt(2) + 2^(1/6)]

show (_)

$\newcommand{\Bold}[1]{\mathbf{#1}}\left[x = -\frac{1}{2} \cdot 2^{\frac{1}{6}} {\left(i \, \sqrt{3} + 1\right)} - \frac{1}{2} \, \sqrt{2}, x = -\frac{1}{2} \cdot 2^{\frac{1}{6}} {\left(-i \, \sqrt{3} + 1\right)} - \frac{1}{2} \, \sqrt{2}, x = -\frac{1}{2} \, \sqrt{2} + 2^{\frac{1}{6}}\right]$

Napokon, koeficijenti mogu biti zadani i kao opći brojevi:

var ('a b c')

(a, b, c)

(a, b, c)

f(x) = expand (a*(x-b)^4 - c)
show (f)

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ a b^{4} - 4 \, a b^{3} x + 6 \, a b^{2} x^{2} - 4 \, a b x^{3} + a x^{4} - c$

solve (f(x) == 0, x)

[x == b - sqrt(-sqrt(c/a)), x == b + sqrt(-sqrt(c/a)), x == b - (c/a)^(1/4), x
== b + (c/a)^(1/4)]

[x == b - sqrt(-sqrt(c/a)), x == b + sqrt(-sqrt(c/a)), x == b - (c/a)^(1/4), x == b + (c/a)^(1/4)]

show (_)

$\newcommand{\Bold}[1]{\mathbf{#1}}\left[x = b - \sqrt{-\sqrt{\frac{c}{a}}}, x = b + \sqrt{-\sqrt{\frac{c}{a}}}, x = b - \left(\frac{c}{a}\right)^{\frac{1}{4}}, x = b + \left(\frac{c}{a}\right)^{\frac{1}{4}}\right]$

Polinom $n$ -tog stupnja ima $n$ nul–točaka. Neke od njih, kao što smo vidjeli, mogu biti kompleksne; ako su koeficijenti polinoma realni brojevi, kompleksne se nul–točke uvijek javljaju u konjugirano–kompleksnim parovima. Osim toga, neke nul–točke mogu biti višestruke:

solve (x^4 - x^3 - 3/4*x^2 + 1/2*x + 1/4 == 0, x)

[x == 1, x == (-1/2)]

[x == 1, x == (-1/2)]

solve (x^4 - x^3 - 3/4*x^2 + 1/2*x + 1/4 == 0, x, multiplicities = True)

([x == 1, x == (-1/2)], [2, 2])

([x == 1, x == (-1/2)], [2, 2])

plot (x^4 - x^3 - 3/4*x^2 + 1/2*x + 1/4, -1, 3/2, figsize = 5)

solve (x^3 - 3*x^2 + 3*x - 1 == 0, x, multiplicities = True)

([x == 1], [3])

([x == 1], [3])

plot (x^3 - 3*x^2 + 3*x - 1, -1, 3, figsize = 5)

solve (x^4 + 8*x^2 + 16 == 0, x, multiplicities = True)

([x == (-2*I), x == (2*I)], [2, 2])

([x == (-2*I), x == (2*I)], [2, 2])

plot (x^4 + 8*x^2 + 16, -4, 4, figsize = 5)

Funkcijom solve() mogu se naći i korijeni nekih polinoma stupnja višega od 4:

f(x) = 3*x^7 + x^6 + 2*x^5 + 3*x^4 - 2*x^3 + x^2 - 2*x
show (f)

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ 3 \, x^{7} + x^{6} + 2 \, x^{5} + 3 \, x^{4} - 2 \, x^{3} + x^{2} - 2 \, x$

plot (f, -1.3, 0.8, figsize = 5)

s = solve (f(x) == 0, x)

for si in s : 
    show (si)

$\newcommand{\Bold}[1]{\mathbf{#1}}x = -\frac{1}{2} \, \sqrt{\frac{1}{3}} \sqrt{\frac{3 \, {\left(\frac{1}{18} \, \sqrt{283} \sqrt{3} + \frac{1}{2}\right)}^{\frac{2}{3}} - 4}{{\left(\frac{1}{18} \, \sqrt{283} \sqrt{3} + \frac{1}{2}\right)}^{\frac{1}{3}}}} - \frac{1}{2} \, \sqrt{-{\left(\frac{1}{18} \, \sqrt{283} \sqrt{3} + \frac{1}{2}\right)}^{\frac{1}{3}} + \frac{6 \, \sqrt{\frac{1}{3}}}{\sqrt{\frac{3 \, {\left(\frac{1}{18} \, \sqrt{283} \sqrt{3} + \frac{1}{2}\right)}^{\frac{2}{3}} - 4}{{\left(\frac{1}{18} \, \sqrt{283} \sqrt{3} + \frac{1}{2}\right)}^{\frac{1}{3}}}}} + \frac{4}{3 \, {\left(\frac{1}{18} \, \sqrt{283} \sqrt{3} + \frac{1}{2}\right)}^{\frac{1}{3}}}}$

$\newcommand{\Bold}[1]{\mathbf{#1}}x = -\frac{1}{2} \, \sqrt{\frac{1}{3}} \sqrt{\frac{3 \, {\left(\frac{1}{18} \, \sqrt{283} \sqrt{3} + \frac{1}{2}\right)}^{\frac{2}{3}} - 4}{{\left(\frac{1}{18} \, \sqrt{283} \sqrt{3} + \frac{1}{2}\right)}^{\frac{1}{3}}}} + \frac{1}{2} \, \sqrt{-{\left(\frac{1}{18} \, \sqrt{283} \sqrt{3} + \frac{1}{2}\right)}^{\frac{1}{3}} + \frac{6 \, \sqrt{\frac{1}{3}}}{\sqrt{\frac{3 \, {\left(\frac{1}{18} \, \sqrt{283} \sqrt{3} + \frac{1}{2}\right)}^{\frac{2}{3}} - 4}{{\left(\frac{1}{18} \, \sqrt{283} \sqrt{3} + \frac{1}{2}\right)}^{\frac{1}{3}}}}} + \frac{4}{3 \, {\left(\frac{1}{18} \, \sqrt{283} \sqrt{3} + \frac{1}{2}\right)}^{\frac{1}{3}}}}$

$\newcommand{\Bold}[1]{\mathbf{#1}}x = \frac{1}{2} \, \sqrt{\frac{1}{3}} \sqrt{\frac{3 \, {\left(\frac{1}{18} \, \sqrt{283} \sqrt{3} + \frac{1}{2}\right)}^{\frac{2}{3}} - 4}{{\left(\frac{1}{18} \, \sqrt{283} \sqrt{3} + \frac{1}{2}\right)}^{\frac{1}{3}}}} - \frac{1}{2} \, \sqrt{-{\left(\frac{1}{18} \, \sqrt{283} \sqrt{3} + \frac{1}{2}\right)}^{\frac{1}{3}} - \frac{6 \, \sqrt{\frac{1}{3}}}{\sqrt{\frac{3 \, {\left(\frac{1}{18} \, \sqrt{283} \sqrt{3} + \frac{1}{2}\right)}^{\frac{2}{3}} - 4}{{\left(\frac{1}{18} \, \sqrt{283} \sqrt{3} + \frac{1}{2}\right)}^{\frac{1}{3}}}}} + \frac{4}{3 \, {\left(\frac{1}{18} \, \sqrt{283} \sqrt{3} + \frac{1}{2}\right)}^{\frac{1}{3}}}}$

$\newcommand{\Bold}[1]{\mathbf{#1}}x = \frac{1}{2} \, \sqrt{\frac{1}{3}} \sqrt{\frac{3 \, {\left(\frac{1}{18} \, \sqrt{283} \sqrt{3} + \frac{1}{2}\right)}^{\frac{2}{3}} - 4}{{\left(\frac{1}{18} \, \sqrt{283} \sqrt{3} + \frac{1}{2}\right)}^{\frac{1}{3}}}} + \frac{1}{2} \, \sqrt{-{\left(\frac{1}{18} \, \sqrt{283} \sqrt{3} + \frac{1}{2}\right)}^{\frac{1}{3}} - \frac{6 \, \sqrt{\frac{1}{3}}}{\sqrt{\frac{3 \, {\left(\frac{1}{18} \, \sqrt{283} \sqrt{3} + \frac{1}{2}\right)}^{\frac{2}{3}} - 4}{{\left(\frac{1}{18} \, \sqrt{283} \sqrt{3} + \frac{1}{2}\right)}^{\frac{1}{3}}}}} + \frac{4}{3 \, {\left(\frac{1}{18} \, \sqrt{283} \sqrt{3} + \frac{1}{2}\right)}^{\frac{1}{3}}}}$

$\newcommand{\Bold}[1]{\mathbf{#1}}x = -\frac{1}{6} i \, \sqrt{23} - \frac{1}{6}$

$\newcommand{\Bold}[1]{\mathbf{#1}}x = \frac{1}{6} i \, \sqrt{23} - \frac{1}{6}$

$\newcommand{\Bold}[1]{\mathbf{#1}}x = 0$

for si in s : 
    show (N (si.rhs()))

$\newcommand{\Bold}[1]{\mathbf{#1}}-1.22074408460576$

$\newcommand{\Bold}[1]{\mathbf{#1}}0.724491959000516$

$\newcommand{\Bold}[1]{\mathbf{#1}}0.248126062802622 - 1.03398206097597i$

$\newcommand{\Bold}[1]{\mathbf{#1}}0.248126062802622 + 1.03398206097597i$

$\newcommand{\Bold}[1]{\mathbf{#1}}-0.166666666666667 - 0.799305253885453i$

$\newcommand{\Bold}[1]{\mathbf{#1}}-0.166666666666667 + 0.799305253885453i$

$\newcommand{\Bold}[1]{\mathbf{#1}}0.000000000000000$

... nekih, ali ne svih...

g(x) = f(x) + 1/2
show (g)

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ 3 \, x^{7} + x^{6} + 2 \, x^{5} + 3 \, x^{4} - 2 \, x^{3} + x^{2} - 2 \, x + \frac{1}{2}$

solve (g(x) == 0, x)

[0 == 6*x^7 + 2*x^6 + 4*x^5 + 6*x^4 - 4*x^3 + 2*x^2 - 4*x + 1]

[0 == 6*x^7 + 2*x^6 + 4*x^5 + 6*x^4 - 4*x^3 + 2*x^2 - 4*x + 1]

show (_)

$\newcommand{\Bold}[1]{\mathbf{#1}}\left[0 = 6 \, x^{7} + 2 \, x^{6} + 4 \, x^{5} + 6 \, x^{4} - 4 \, x^{3} + 2 \, x^{2} - 4 \, x + 1\right]$

plot (g(x), -1.3, 0.8, figsize = 5)

Funkcija solve() može zatražiti pomoć funkcije to_poly_solve() programskog paketa Maxima (koji je „ugrađen” u SageMath), ali će pritom često pronaći približna, a ne točna rješenja:

solve (g(x) == 0, x, to_poly_solve = 'force')

[x == -1.232674118658641,
 x == 0.2782547748379183,
 x == 0.6333373978783076,
 x == (0.2357507950017957 - 1.068709145725271*I),
 x == (-0.2418764787770275 - 0.762933981471788*I),
 x == (-0.2418764787770275 + 0.762933981471788*I),
 x == (0.2357507950017957 + 1.068709145725271*I)]

[x == -1.232674118658641,
 x == 0.2782547748379183,
 x == 0.6333373978783076,
 x == (0.2357507950017957 - 1.068709145725271*I),
 x == (-0.2418764787770275 - 0.762933981471788*I),
 x == (-0.2418764787770275 + 0.762933981471788*I),
 x == (0.2357507950017957 + 1.068709145725271*I)]

Funkcijom solve(), potpomognutom funkcijom to_poly_solve(), mogu se naći i nul–točke još nekih funkcija:

f(x) = x/sqrt (x^2 + 1) - 1/2
show (f)

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ \frac{x}{\sqrt{x^{2} + 1}} - \frac{1}{2}$

solve (f(x) == 0, x)

[x == 1/2*sqrt(x^2 + 1)]

[x == 1/2*sqrt(x^2 + 1)]

show (_)

$\newcommand{\Bold}[1]{\mathbf{#1}}\left[x = \frac{1}{2} \, \sqrt{x^{2} + 1}\right]$

plot (f, 0, 1, figsize = 5)

solve (f(x) == 0, x, to_poly_solve = 'force')

[x == 1/3*sqrt(3)]

[x == 1/3*sqrt(3)]

N (_[0].rhs())

0.577350269189626

0.577350269189626

... nekih, ali ne svih...

g(x) = f(x) + x
show (g)

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ x + \frac{x}{\sqrt{x^{2} + 1}} - \frac{1}{2}$

plot (g, 0, 1, figsize = 5)

solve (g(x) == 0, x, to_poly_solve = 'force')

[]

[]

Ako funkcija ima beskonačno mnogo (periodičnih) korijena, za njihov će prikaz biti uvedena pomoćna varijabla; varijable oblika zNN su cjelobrojne, a oblika rNN realne:

plot (sin (x) - cos (2*x), 0, 5*pi, figsize = 5)

solve (sin (x) - cos (2*x) == 0, x, to_poly_solve = 'force')

[x == -1/2*pi + 2*pi*z39, x == 5/6*pi + 2*pi*z41, x == 1/6*pi + 2*pi*z43]

[x == -1/2*pi + 2*pi*z39, x == 5/6*pi + 2*pi*z41, x == 1/6*pi + 2*pi*z43]

show (_)

$\newcommand{\Bold}[1]{\mathbf{#1}}\left[x = -\frac{1}{2} \, \pi + 2 \, \pi z_{39}, x = \frac{5}{6} \, \pi + 2 \, \pi z_{41}, x = \frac{1}{6} \, \pi + 2 \, \pi z_{43}\right]$

Korijeni polinoma

Približne vrijednosti korijena polinoma možemo naći funkcijom .roots(). Ona nalazi i korijene polinoma stupnjeva viših od 4. Pritom treba funkcijom .polynomial() „opću” funkciju „pretvoriti” u polinom navodeći kojemu skupu brojeva pripadaju njegovi koeficijenti — u istom će se skupu tražiti i korijeni, a funkcija nalazi sve korijene koji su u njemu.

f(x) = 3*x^7 + x^6 + 2*x^5 + 3*x^4 - 2*x^3 + x^2 - 2*x + 1/2

plot (f, -1.3, 0.9, figsize = 5)

f.polynomial(QQ).roots()

[]

[]

f.polynomial(RR).roots()

[(-1.23267411590233, 1), (0.278254759437390, 1), (0.633337390682075, 1)]

[(-1.23267411590233, 1), (0.278254759437390, 1), (0.633337390682075, 1)]

f.polynomial(CC).roots()

[(-1.23267411590233, 1),
 (0.278254759437390, 1),
 (0.633337390682075, 1),
 (-0.241876478777028 - 0.762933981471788*I, 1),
 (-0.241876478777028 + 0.762933981471788*I, 1),
 (0.235750795001795 - 1.06870914572527*I, 1),
 (0.235750795001795 + 1.06870914572527*I, 1)]

[(-1.23267411590233, 1),
 (0.278254759437390, 1),
 (0.633337390682075, 1),
 (-0.241876478777028 - 0.762933981471788*I, 1),
 (-0.241876478777028 + 0.762933981471788*I, 1),
 (0.235750795001795 - 1.06870914572527*I, 1),
 (0.235750795001795 + 1.06870914572527*I, 1)]

Rezultat funkcije .roots() je lista uređenih parova: prva je komponenta para vrijednost korijena, a druga njegova „strukost”. Ako nas „strukosti” ne zanimaju, možemo zatražiti i samo listu vrijednosti:

f.polynomial(RR) . roots (multiplicities = False)

[-1.23267411590233, 0.278254759437390, 0.633337390682075]

[-1.23267411590233, 0.278254759437390, 0.633337390682075]

Postoji uska veza između korijena polinoma i rastavljanja polinoma na faktore (o kojemu je bilo riječi na drugom predavanju): ako su $x_1,\, x_1,\,\ldots,\,x_n$ realni i kompleksni korijeni polinoma

$P_n (x) \,=\, a_n x^n + a_{n_1} x^{n-1} + \cdots + a_2 x^2 + a_1 x + a_0$ ,

onda je njegova faktorizacija

$P_n (x) \,=\, a_n\cdot(x - x_1)\cdot(x - x_2)\cdots(x - x_n)$ .

f.polynomial(CC).factor()

(3.00000000000000) * (x - 0.633337390682075) * (x - 0.278254759437390) * (x -
0.235750795001795 - 1.06870914572527*I) * (x - 0.235750795001795 +
1.06870914572527*I) * (x + 0.241876478777028 - 0.762933981471788*I) * (x +
0.241876478777028 + 0.762933981471788*I) * (x + 1.23267411590233)

(3.00000000000000) * (x - 0.633337390682075) * (x - 0.278254759437390) * (x - 0.235750795001795 - 1.06870914572527*I) * (x - 0.235750795001795 + 1.06870914572527*I) * (x + 0.241876478777028 - 0.762933981471788*I) * (x + 0.241876478777028 + 0.762933981471788*I) * (x + 1.23267411590233)

show (_)

$\newcommand{\Bold}[1]{\mathbf{#1}}\left(3.00000000000000\right) \cdot (x - 0.633337390682075) \cdot (x - 0.278254759437390) \cdot (x - 0.235750795001795 - 1.06870914572527i) \cdot (x - 0.235750795001795 + 1.06870914572527i) \cdot (x + 0.241876478777028 - 0.762933981471788i) \cdot (x + 0.241876478777028 + 0.762933981471788i) \cdot (x + 1.23267411590233)$

Ako $P_n$ zadamo na skupu $\mathbb{R}$ , u rastavu se mogu pojaviti i polinomi drugoga stupnja (koji nemaju korijena u skupu $\mathbb{R}$ , nego u skupu $\mathbb{C}$ ):

f.polynomial(RR).factor()

(3.00000000000000) * (x - 0.633337390682075) * (x - 0.278254759437390) * (x +
1.23267411590233) * (x^2 - 0.471501590003590*x + 1.19771767550081) * (x^2 +
0.483752957554055*x + 0.640572491069968)

(3.00000000000000) * (x - 0.633337390682075) * (x - 0.278254759437390) * (x + 1.23267411590233) * (x^2 - 0.471501590003590*x + 1.19771767550081) * (x^2 + 0.483752957554055*x + 0.640572491069968)

show (_)

$\newcommand{\Bold}[1]{\mathbf{#1}}\left(3.00000000000000\right) \cdot (x - 0.633337390682075) \cdot (x - 0.278254759437390) \cdot (x + 1.23267411590233) \cdot (x^{2} - 0.471501590003590 x + 1.19771767550081) \cdot (x^{2} + 0.483752957554055 x + 0.640572491069968)$

Numeričko rješavanje nelinearnih jednadžbi s jednom nepoznanicom

Razmjerno se mali broj „općih” nelinearnih jednadžbi može točno riješiti.

g(x) = x/sqrt (x^2 + 1) + x - 1/2
show (g)

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ x + \frac{x}{\sqrt{x^{2} + 1}} - \frac{1}{2}$

solve (g(x) == 0, x, to_poly_solve = 'force')

[]

[]

plot (g, -1, 1, figsize = 5)

Nelinearne se jednadžbe rješavaju, odnosno, što je isto, nul–točke nelinearnih funkcija određuju se stoga najčešće različitim numeričkim iteracijskim postupcima, što znači postupnim približavanjem u nizu sve točnijih, ali ipak uvijek tek približnih rješenja: iteracijski se postupak prekida kad je $|f(x)| < \tau$ , gdje je $\tau$ zadana točnost.

Numeričkom određivanju korijena funkcije jedne varijable namijenjena je funkcija find_root(). Za njezinu primjenu treba zadati i krajeve intervala u kojemu se traženi korijen nalazi. Taj se interval može odrediti pomoću grafa funkcije.

x0 = find_root (g, 0., 1.)
x0; g (x0)

0.25390434474389206
4.718447854656915e-16

0.25390434474389206
4.718447854656915e-16

find_root (g, 2., 3.)

Traceback (click to the left of this block for traceback)
...
RuntimeError: f appears to have no zero on the interval

Traceback (most recent call last):
  File "<stdin>", line 1, in <module>
  File "_sage_input_5.py", line 10, in <module>
    exec compile(u'open("___code___.py","w").write("# -*- coding: utf-8 -*-\\n" + _support_.preparse_worksheet_cell(base64.b64decode("ZmluZF9yb290IChnLCAyLiwgMy4p"),globals())+"\\n"); execfile(os.path.abspath("___code___.py"))
  File "", line 1, in <module>
    
  File "/tmp/tmpRlLtdq/___code___.py", line 3, in <module>
    exec compile(u'find_root (g, _sage_const_2p , _sage_const_3p )
  File "", line 1, in <module>
    
  File "sage/misc/lazy_import.pyx", line 354, in sage.misc.lazy_import.LazyImport.__call__ (build/cythonized/sage/misc/lazy_import.c:3756)
  File "/opt/SageMath/local/lib/python2.7/site-packages/sage/numerical/optimize.py", line 82, in find_root
    return f.find_root(a=a,b=b,xtol=xtol,rtol=rtol,maxiter=maxiter,full_output=full_output)
  File "sage/symbolic/expression.pyx", line 11785, in sage.symbolic.expression.Expression.find_root (build/cythonized/sage/symbolic/expression.cpp:66672)
  File "/opt/SageMath/local/lib/python2.7/site-packages/sage/numerical/optimize.py", line 100, in find_root
    raise RuntimeError("f appears to have no zero on the interval")
RuntimeError: f appears to have no zero on the interval

Podrazumijeva se točnost $\tau = 1\cdot 10^{-12}$ , ali se ona može i povećati ili smanjiti.

x0 = find_root (g, 0., 1., xtol = 1e-5)
x0; g (x0)

0.2539066336808675
4.373115521649762e-06

0.2539066336808675
4.373115521649762e-06

Ako funkcija ima više nul–točaka, možemo ih naći pogodnim odabirom intervala.

g2(x) = x^4 - 3*x^2 + 4/3

plot (g2, -2, 2, figsize = 5)

find_root (g2, -2., -1.)

-1.567618291471598

-1.567618291471598

find_root (g2, -1., 0.)

-0.73659547395003

-0.73659547395003

find_root (g2, 0., 1.)

0.73659547395003

0.73659547395003

find_root (g2, 1., 2.)

1.567618291471598

1.567618291471598

Ako zadamo interval u kojem se nalazi više nul–točaka, find_root() će naći jednu od njih:

find_root (g2, 0., 2.)

1.5676182914716

1.5676182914716

find_root (g2, -2., 0.)

-0.736595473950025

-0.736595473950025

find_root (g2, -2., 2.)

-0.7365954739500242

-0.7365954739500242

Možemo dobiti i potpunije podatke o iteracijskom postupku.

f(x) = (x-5)/sqrt((x-5)^2 + 1) + (x+1)/sqrt((x+1)^2 + 16)
show (f)

$\newcommand{\Bold}[1]{\mathbf{#1}}x \ {\mapsto}\ \frac{x + 1}{\sqrt{{\left(x + 1\right)}^{2} + 16}} + \frac{x - 5}{\sqrt{{\left(x - 5\right)}^{2} + 1}}$

plot (f, -10, 10, figsize = 5)

x0, r = find_root (f, 2., 5., full_output = True)

x0

3.7999999999999217

3.7999999999999217

r

      converged: True
           flag: 'converged'
 function_calls: 10
     iterations: 9
           root: 3.7999999999999217

      converged: True
           flag: 'converged'
 function_calls: 10
     iterations: 9
           root: 3.7999999999999217

x0, r = find_root (f(x) == 0, 3.7825, 3.8025, full_output = True)

x0

3.8000000000000007

3.8000000000000007

r

      converged: True
           flag: 'converged'
 function_calls: 6
     iterations: 5
           root: 3.8000000000000007

      converged: True
           flag: 'converged'
 function_calls: 6
     iterations: 5
           root: 3.8000000000000007

x0, r = find_root (f, 2., 5., xtol = 1e-5, full_output = True)

x0

3.799999982477675

3.799999982477675

r

      converged: True
           flag: 'converged'
 function_calls: 8
     iterations: 7
           root: 3.799999982477675

      converged: True
           flag: 'converged'
 function_calls: 8
     iterations: 7
           root: 3.799999982477675

Sustavi linearnih algebarskih jednadžbi

Manji sustavi linearnih jednadžbi mogu se riješiti funkcijom solve().

Jednadžbe se navode u listi, a sve nepoznanice moraju prethodno biti „uvedene” kao varijable:

var ('x y z')

(x, y, z)

(x, y, z)

solve ([3*x + 2*y + z == 6, 5*x + 6*y + 4*z == 15, 7*x + 8*y + 9*z == 24], [x, y, z])

[[x == 1, y == 1, z == 1]]

[[x == 1, y == 1, z == 1]]

... ili (možda) preglednije napisano:

solve ([3*x + 2*y + z == 6, 
        5*x + 6*y + 4*z == 15, 
        7*x + 8*y + 9*z == 24], 
        [x, y, z])

[[x == 1, y == 1, z == 1]]

[[x == 1, y == 1, z == 1]]

Sustav može imati jedinstveno rješenje ili beskonačno mnogo njih, a može i ne imati rješenje:

solve ([x + 2*y + 3*z == 6, 
        4*x + 5*y + 6*z == 15, 
        7*x + 8*y + 9*z == 24], 
        [x, y, z])

[[x == r2, y == -2*r2 + 3, z == r2]]

[[x == r2, y == -2*r2 + 3, z == r2]]

show (_)

$\newcommand{\Bold}[1]{\mathbf{#1}}\left[\left[x = r_{4}, y = -2 \, r_{4} + 3, z = r_{4}\right]\right]$

solve ([x + 2*y + 3*z == 6, 
        4*x + 5*y + 6*z == 15, 
        7*x + 8*y + 9*z == 25], 
        [x, y, z])

[]

[]

Veće je sustave pogodnije prikazati u matričnom obliku $\mathbf{A}\, \mathbf{x} = \mathbf{b}$ .

Primjerice, za sustav

$a_{0,0}\,x_0 + a_{0,1}\,x_1 + a_{0,2}\,x_2 \,=\, b_0$

$a_{1,0}\,x_0 + a_{1,1}\,x_1 + a_{1,2}\,x_2 \,=\, b_1$

$a_{2,0}\,x_0 + a_{2,1}\,x_1 + a_{2,2}\,x_2 \,=\, b_2$

$\mathbf{A} = \left[ \begin{array}{ccc} a_{0,0} & a_{0,1} & a_{0,2} \\ a_{1,0} & a_{1,1} & a_{1,2} \\ a_{2,0} & a_{2,1} & a_{2,2} \end{array} \right]$ , $\mathbf{b} = \left[ \begin{array}{c} b_0 \\ b_1 \\ b_2 \end{array} \right]$ i $\mathbf{x} = \left[ \begin{array}{c} x_0 \\ x_1 \\ x_2 \end{array} \right]$ ,

dok su za sustav

$4\, x_0 - x_1 - x_2 - x_5 \,=\, 5$

$-x_0 + 4\, x_1 - x_2 - x3 \,=\, -5$

$-x_0 - x_1 + 4\, x_2 - x_3 - x_4 \,=\, 4$

$-x_1 - x_2 + 4\, x_3 - x_4 - x_5 \,=\, -6$

$-x_2 - x_3 + 4\, x_4 - x_5 \,=\, -5$

$-x_0 - x_3 - x_4 + 4\, x_5 \,=\, -5$

matrica sustava $\mathbf{A}$ i vektor slobodnih članova $\mathbf{b}$ (uzmemo li da su koeficijenti u jednadžbama „realni”)

A = matrix (RR, [[4, -1, -1, 0, 0, -1], 
                 [-1, 4, -1, -1, 0, 0], 
                 [-1, -1, 4, -1, -1, 0], 
                 [0, -1, -1, 4, -1, -1], 
                 [0, 0, -1, -1, 4, -1],
                 [-1, 0, 0, -1, -1, 4]])
show (A.n (digits = 3))

$\newcommand{\Bold}[1]{\mathbf{#1}}\left(\begin{array}{rrrrrr} 4.00 & -1.00 & -1.00 & 0.000 & 0.000 & -1.00 \\ -1.00 & 4.00 & -1.00 & -1.00 & 0.000 & 0.000 \\ -1.00 & -1.00 & 4.00 & -1.00 & -1.00 & 0.000 \\ 0.000 & -1.00 & -1.00 & 4.00 & -1.00 & -1.00 \\ 0.000 & 0.000 & -1.00 & -1.00 & 4.00 & -1.00 \\ -1.00 & 0.000 & 0.000 & -1.00 & -1.00 & 4.00 \end{array}\right)$

b = vector (RR, [5, -5, 4, -6, -5, -3])
show (b.column().n (digits = 3))

$\newcommand{\Bold}[1]{\mathbf{#1}}\left(\begin{array}{r} 5.00 \\ -5.00 \\ 4.00 \\ -6.00 \\ -5.00 \\ -3.00 \end{array}\right)$

x = A.solve_right (b)

... ili:

x = A \ b

show (x.column())

$\newcommand{\Bold}[1]{\mathbf{#1}}\left(\begin{array}{r} -0.670329670329670 \\ -2.95604395604396 \\ -1.85714285714286 \\ -4.29670329670330 \\ -3.50549450549450 \\ -2.86813186813187 \end{array}\right)$

Ako su koeficijenti u jednadžbama racionalni brojevi, onda su

D = matrix (QQ, [[4, -1, -1, 0, 0, -1], 
                 [-1, 4, -1, -1, 0, 0], 
                 [-1, -1, 4, -1, -1, 0], 
                 [0, -1, -1, 4, -1, -1], 
                 [0, 0, -1, -1, 4, -1],
                 [-1, 0, 0, -1, -1, 4]])
show (D)

$\newcommand{\Bold}[1]{\mathbf{#1}}\left(\begin{array}{rrrrrr} 4 & -1 & -1 & 0 & 0 & -1 \\ -1 & 4 & -1 & -1 & 0 & 0 \\ -1 & -1 & 4 & -1 & -1 & 0 \\ 0 & -1 & -1 & 4 & -1 & -1 \\ 0 & 0 & -1 & -1 & 4 & -1 \\ -1 & 0 & 0 & -1 & -1 & 4 \end{array}\right)$

c = vector (QQ, [5, -5, 4, -6, -5, -3])
show (c.column())

$\newcommand{\Bold}[1]{\mathbf{#1}}\left(\begin{array}{r} 5 \\ -5 \\ 4 \\ -6 \\ -5 \\ -3 \end{array}\right)$

y = D \ c
show (y.column())

$\newcommand{\Bold}[1]{\mathbf{#1}}\left(\begin{array}{r} -\frac{61}{91} \\ -\frac{269}{91} \\ -\frac{13}{7} \\ -\frac{391}{91} \\ -\frac{319}{91} \\ -\frac{261}{91} \end{array}\right)$

reset ('x y')

Sustavi nelinearnih algebarskih jednadžbi

Tek se rijetki manji sustavi nelinearnih jednadžbi mogu točno riješiti.

var ('y')
f (x, y) = x*y
g (x, y) = x^2 - y^2 - 0.25

pf = plot3d (f, (-1, 1), (-1, 1), color = 'red')
pg = plot3d (g, (-1, 1), (-1, 1), color = 'green')
pz0 = plot3d (0, (-1, 1), (-1, 1))
pf + pg + pz0

Click on 3-D image to make it live. Right-click on live image for a control menu.

pif = implicit_plot (f (x, y) == 0, (x, -1, 1), (y, -1, 1), color = 'red', figsize = 6)
pig = implicit_plot (g (x, y) == 0, (x, -1, 1), (y, -1, 1), color = 'green', figsize = 6)
pif + pig

solve ([f (x, y) == 0, 
        g (x, y) == 0], 
       [x, y])

[[x == (1/2), y == 0], [x == (-1/2), y == 0], [x == 0, y == (-1/2*I)], [x == 0,
y == (1/2*I)]]

[[x == (1/2), y == 0], [x == (-1/2), y == 0], [x == 0, y == (-1/2*I)], [x == 0, y == (1/2*I)]]

show (_)

$\newcommand{\Bold}[1]{\mathbf{#1}}\left[\left[x = \left(\frac{1}{2}\right), y = 0\right], \left[x = \left(-\frac{1}{2}\right), y = 0\right], \left[x = 0, y = \left(-\frac{1}{2} i\right)\right], \left[x = 0, y = \left(\frac{1}{2} i\right)\right]\right]$

Sustavi nelinearnih algebarskih jednadžbi mogu se numerički rješavati primjenom funkcija modula optimize (Optimization and root finding) programskoga paketa SciPy, uključenog i u SageMath, ali to je druga — i razmjerno duga — priča.

Nejednadžbe

Funkcijom mogu se rješavati i nejednadžbe. Rješenja nejednadžbi konačni su ili beskonačni odsječci osi $x$ .

p = plot (x^2 - 2*x - 2, -3/2, 7/2, figsize = 5)
p

solve (x^2 - 2*x - 2 < 0, x)

[[x > -sqrt(3) + 1, x < sqrt(3) + 1]]

[[x > -sqrt(3) + 1, x < sqrt(3) + 1]]

show (_)

$\newcommand{\Bold}[1]{\mathbf{#1}}\left[\left[x > -\sqrt{3} + 1, x < \sqrt{3} + 1\right]\right]$

... vrijednosti funkcije $x^2 - 2\,x - 2$ bit će negativne ako je $x\in (-\sqrt{3}+1, \sqrt{3}+1)$ .

solve (x^2 - 2*x - 2 > 0, x)

[[x < -sqrt(3) + 1], [x > sqrt(3) + 1]]

[[x < -sqrt(3) + 1], [x > sqrt(3) + 1]]

show (_)

$\newcommand{\Bold}[1]{\mathbf{#1}}\left[\left[x < -\sqrt{3} + 1\right], \left[x > \sqrt{3} + 1\right]\right]$

... vrijednosti funkcije $x^2 - 2\,x - 2$ bit će pozitivne ako je $x\in (-\infty, -\sqrt{3}+1)$ ili ako je $x\in (\sqrt{3}+1, \infty)$ .

p1 = plot (x^2, -1, 3, figsize = 5, color = 'red')
p2 = plot (2*x + 2, -1, 3, figsize = 5, color = 'red')
p + p1 + p2

solve (x^2 > 2*x + 2, x)

[[x < -sqrt(3) + 1], [x > sqrt(3) + 1]]

[[x < -sqrt(3) + 1], [x > sqrt(3) + 1]]

show (_)

$\newcommand{\Bold}[1]{\mathbf{#1}}\left[\left[x < -\sqrt{3} + 1\right], \left[x > \sqrt{3} + 1\right]\right]$

... vrijednosti funkcije $x^2$ bit će veće od vrijednosti funkcije $2\,x + 2$ ako je $x\in (-\infty, -\sqrt{3}+1)$ ili ako je $x\in (\sqrt{3}+1, \infty)$ .

solve (x^2 < 2*x + 2, x)

[[x > -sqrt(3) + 1, x < sqrt(3) + 1]]

[[x > -sqrt(3) + 1, x < sqrt(3) + 1]]

show (_)

$\newcommand{\Bold}[1]{\mathbf{#1}}\left[\left[x > -\sqrt{3} + 1, x < \sqrt{3} + 1\right]\right]$

... vrijednosti funkcije $x^2$ bit će manje od vrijednosti funkcije $2\,x + 2$ ako je $x\in (-\sqrt{3}+1, \sqrt{3}+1)$ .

plot (x^2 + 1, -1, 1, figsize = 5)

solve (x^2 + 1 > 0, x)

[x < +Infinity]

[x < +Infinity]

... vrijednosti funkcije $x^2 + 1$ pozitivne su za sve $x$ (koji su manji od $\infty$ ).

solve (x^2 + 1 < 0, x)

[]

[]

... niti jedna vrijednost funkcije $x^2 + 1$ nije negativna.

Nejednadžbe i njihove sustave primjenjujemo u određivanju domena funkcija. Nažalost, SageMath će ponekad zatrebati našu pomoć u rješavanju sustava nejednadžbi: problem ćemo morati riješiti u nekoliko koraka.

Primjerica, neka je $f(x) = \dfrac{\sqrt{(x-2)^2 - 4}}{\ln\, (x+4)}$ . Treba odrediti domenu funkcije $f$ . Podsjećamo:

izraz $\sqrt{x}$ poprima realne vrijednosti za $x \ge 0$ ;
izraz $\ln x$ poprima konačne realne vrijednosti za $x > 0$ ;
izraz $x/y$ je definiran za $y \ne 0$ .

plot (sqrt ((x-2)^2 - 4)/(ln (x + 4)), -6, 6, ymin = -20, ymax = 20, detect_poles = 'show')

verbose 0 (3763: plot.py, generate_plot_points) WARNING: When plotting, failed
to evaluate function at 101 points.
verbose 0 (3763: plot.py, generate_plot_points) Last error message: 'math domain
error'

verbose 0 (3763: plot.py, generate_plot_points) WARNING: When plotting, failed to evaluate function at 101 points.
verbose 0 (3763: plot.py, generate_plot_points) Last error message: 'math domain error'

solve ([(x-2)^2 - 4 >= 0, x + 4 > 0, log (x + 4) != 0], x)

[[-4 < x, x < 0, log(x + 4) != 0], [4 < x, log(x + 4) != 0], [x == 0,
2*log(2) != 0], [x == 4, 3*log(2) != 0]]

[[-4 < x, x < 0, log(x + 4) != 0], [4 < x, log(x + 4) != 0], [x == 0, 2*log(2) != 0], [x == 4, 3*log(2) != 0]]

show (_)

$\newcommand{\Bold}[1]{\mathbf{#1}}\left[\left[\left(-4\right) < x, x < 0, \log\left(x + 4\right) \neq 0\right], \left[4 < x, \log\left(x + 4\right) \neq 0\right], \left[x = 0, 2 \, \log\left(2\right) \neq 0\right], \left[x = 4, 3 \, \log\left(2\right) \neq 0\right]\right]$

solve ([(x-2)^2 - 4 >= 0, x + 4 > 0], x)

[[-4 < x, x < 0], [4 < x], [x == 0], [x == 4]]

[[-4 < x, x < 0], [4 < x], [x == 0], [x == 4]]

solve (log (x + 4) != 0, x)

#0: solve_rat_ineq(ineq=log(_SAGE_VAR_x+4) # 0)
[[log(x + 4) != 0]]

#0: solve_rat_ineq(ineq=log(_SAGE_VAR_x+4) # 0)
[[log(x + 4) != 0]]

solve (log (x + 4) == 0, x)

[x == -3]

[x == -3]

... domena funkcije $f$ je $(-4, 0] \!\setminus\!\{-3\} \cup [4, \infty)$ .

Kao drugi primjer, neka je $f(x) = \dfrac{\sqrt{(x-2)^2 - \frac{1}{2}}}{\ln x}$ .

plot (sqrt ((x-2)^2 - 1/2)/(ln (x)), -2, 4, ymin = -20, ymax = 20, detect_poles = 'show')

verbose 0 (3763: plot.py, generate_plot_points) WARNING: When plotting, failed
to evaluate function at 114 points.
verbose 0 (3763: plot.py, generate_plot_points) Last error message: 'math domain
error'

verbose 0 (3763: plot.py, generate_plot_points) WARNING: When plotting, failed to evaluate function at 114 points.
verbose 0 (3763: plot.py, generate_plot_points) Last error message: 'math domain error'

solve ([(x-2)^2 - 1/2 >= 0, x > 0], x)

[[0 < x, 2*x^2 - 8*x + 7 == 0], [0 < x, 2*x^2 - 8*x + 7 > 0]]

[[0 < x, 2*x^2 - 8*x + 7 == 0], [0 < x, 2*x^2 - 8*x + 7 > 0]]

solve((x-2)^2 - 1/2 >= 0, x)

[[x <= -1/2*sqrt(2) + 2], [x >= 1/2*sqrt(2) + 2]]

[[x <= -1/2*sqrt(2) + 2], [x >= 1/2*sqrt(2) + 2]]

solve ([x <= -1/2*sqrt(2) + 2, x > 0], x)

[[0 < x, x < -1/2*sqrt(2) + 2], [x == -1/2*sqrt(2) + 2]]

[[0 < x, x < -1/2*sqrt(2) + 2], [x == -1/2*sqrt(2) + 2]]

solve ([x >= 1/2*sqrt(2) + 2, x > 0], x)

[[1/2*sqrt(2) + 2 < x], [x == 1/2*sqrt(2) + 2]]

[[1/2*sqrt(2) + 2 < x], [x == 1/2*sqrt(2) + 2]]

solve (log (x) == 0, x)

[x == 1]

[x == 1]

... domena funkcije $f$ je $(0, 2-\frac{1}{2}\sqrt{2}] \!\setminus\!\{1\} \cup [2+\frac{1}{2}\sqrt{2}, \infty)$ .

MPZI_predavanje_06

2462 days ago by fresl